build-aux/update-copyright

   1 #!/usr/bin/perl -0777 -pi
   2 # Update an FSF copyright year list to include the current year.
   3
   4 my $VERSION = '2009-07-31.12:44'; # UTC
   5
   6 # Copyright (C) 2009 Free Software Foundation
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3, or (at your option)
  11 # any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # Written by Jim Meyering
  22
  23 # The arguments to this script should be names of files that contain FSF
  24 # copyright statements to be updated.  For example, you may wish to
  25 # place a target like the following in your top-level makefile in your
  26 # project:
  27 #
  28 #   .PHONY: update-copyright
  29 #   update-copyright:
  30 #       if test -d .git; then                                   \
  31 #         git grep -l -w Copyright                              \
  32 #           | grep -v -E '(^|/)(COPYING|ChangeLog)'             \
  33 #           | xargs $(srcdir)/build-aux/$@;                     \
  34 #       fi
  35 #
  36 # In the second grep, you can build a list of files to skip within your
  37 # project.
  38 #
  39 # Iff an FSF copyright statement is discovered in a file and the final
  40 # year is not the current year, the statement is updated for the new
  41 # year and reformatted to fit within 72 columns.  A warning is printed
  42 # for every file for which no FSF copyright statement is discovered.
  43 #
  44 # Each file's FSF copyright statement must be formated correctly in
  45 # order to be recognized, and it must appear before other text that
  46 # looks like the start of a copyright statement.  For example, each of
  47 # these by itself is fine:
  48 #
  49 #   Copyright (C) 1990-2005, 2007-2009 Free Software Foundation,
  50 #   Inc.
  51 #
  52 #   # Copyright (C) 1990-2005, 2007-2009 Free Software
  53 #   # Foundation, Inc.
  54 #
  55 #   /*
  56 #    * Copyright (C) 90,2005,2007-2009 Free Software
  57 #    * Foundation, Inc.
  58 #    */
  59 #
  60 # However, the following format is not recognized because the line
  61 # prefix changes after the first line:
  62 #
  63 #   /* Copyright (C) 1990-2005, 2007-2009 Free Software
  64 #    * Foundation, Inc.  */
  65 #
  66 # The following copyright statement is not recognized because the
  67 # copyright holder is not the FSF:
  68 #
  69 #   Copyright (C) 1990-2005, 2007-2009 Acme, Inc.
  70 #
  71 # Moreover, any FSF copyright statement following either of the previous
  72 # copyright statements might not be recognized.
  73 #
  74 # The exact conditions that a file's FSF copyright statement must meet
  75 # to be recognized are listed below.  They may seem slightly complex,
  76 # but you need not worry if some file in your project accidentally
  77 # breaks one.  The worse that can happen is a warning that the file was
  78 # not updated.
  79 #
  80 #   1. The format is "Copyright (C)" (where "(C)" can be "(c)"), then a
  81 #      list of copyright years, and then the name of the copyright
  82 #      holder, which is "Free Software Foundation, Inc.".
  83 #   2. "Copyright (C)" appears at the beginning of a line except that it
  84 #      may be prefixed by any sequence (e.g., a comment) of no more than
  85 #      5 characters.
  86 #   3. The prefix of "Copyright (C)" is the same as the prefix on the
  87 #      file's first occurrence of "Copyright (C)" that matches condition
  88 #      #2.  Stated more simply, if something that looks like the start
  89 #      of a copyright statement appears earlier than the FSF copyright
  90 #      statement, the FSF copyright statement might not be recognized.
  91 #      This condition might be removed in the future.
  92 #   4. Iff a prefix is present before "Copyright (C)", the same prefix
  93 #      appears at the beginning of each remaining line within the FSF
  94 #      copyright statement.
  95 #   5. Blank lines, even if preceded by the prefix, do not appear
  96 #      within the FSF copyright statement.
  97 #   6. Each copyright year is 2 or 4 digits, and years are separated by
  98 #      commas or dashes.  Whitespace may occur after commas.
  99
 100 use strict;
 101 use warnings;
 102
 103 my ($sec, $min, $hour, $mday, $month, $year) = localtime (time());
 104 my $this_year = $year + 1900;
 105 my $copyright = 'Copyright \([cC]\)';
 106 my $holder = 'Free Software Foundation, Inc.';
 107 my $prefix_max = 5;
 108 my $margin = 72;
 109
 110 # Unless the file consistently uses "\r\n" as the EOL, use "\n" instead.
 111 my $eol = /(?:^|[^\r])\n/ ? "\n" : "\r\n";
 112
 113 my $leading;
 114 my $prefix;
 115 my $ws;
 116 my $old;
 117 if (/(^|\n)(.{0,$prefix_max})$copyright/)
 118   {
 119     $leading = $1;
 120     $prefix = $2;
 121     $ws = '[ \t\r\f]'; # \s without \n
 122     $ws = "(?:$ws*(?:$ws|\\n" . quotemeta($prefix) . ")$ws*)";
 123     $holder =~ s/\s/$ws/g;
 124     $old =
 125       quotemeta("$leading$prefix") . "($copyright$ws"
 126       . "(?:(?:\\d\\d)?\\d\\d(,$ws?|-))*"
 127       . "((?:\\d\\d)?\\d\\d)$ws$holder)";
 128   }
 129 if (defined($old) && /$old/)
 130   {
 131     my $new = $1;
 132     my $sep = $2 ? $2 : "";
 133     my $last_c_year = $3;
 134
 135     # Handle two-digit year numbers like "98" and "99".
 136     $last_c_year <= 99
 137       and $last_c_year += 1900;
 138
 139     if ($last_c_year != $this_year)
 140       {
 141         # Update the year.
 142         if ($sep eq '-' && $last_c_year + 1 == $this_year)
 143           {
 144             $new =~ s/$last_c_year/$this_year/;
 145           }
 146         elsif ($sep ne '-' && $last_c_year + 1 == $this_year)
 147           {
 148             $new =~ s/$last_c_year/$last_c_year-$this_year/;
 149           }
 150         else
 151           {
 152             $new =~ s/$last_c_year/$last_c_year, $this_year/;
 153           }
 154
 155         # Normalize all whitespace including newline-prefix sequences.
 156         $new =~ s/$ws/ /g;
 157
 158         # Put spaces after commas.
 159         $new =~ s/, ?/, /g;
 160
 161         # Format within margin.
 162         my $new_wrapped;
 163         my $text_margin = $margin - length($prefix);
 164         while (length($new))
 165           {
 166             if (($new =~ s/^(.{1,$text_margin})(?: |$)//)
 167                 || ($new =~ s/^([\S]+)(?: |$)//))
 168               {
 169                 my $line = $1;
 170                 $new_wrapped .= $new_wrapped ? $eol : $leading;
 171                 $new_wrapped .= "$prefix$line";
 172               }
 173             else
 174               {
 175                 # Should be unreachable, but we don't want an infinite
 176                 # loop if it can be reached.
 177                 die;
 178               }
 179           }
 180
 181         # Replace the old copyright statement.
 182         s/$old/$new_wrapped/;
 183       }
 184   }
 185 else
 186   {
 187     print STDERR "$ARGV: warning: FSF copyright statement not found\n";
 188   }
 189
 190 # Local variables:
 191 # indent-tabs-mode: nil
 192 # eval: (add-hook 'write-file-hooks 'time-stamp)
 193 # time-stamp-start: "my $VERSION = '"
 194 # time-stamp-format: "%:y-%02m-%02d.%02H:%02M"
 195 # time-stamp-time-zone: "UTC"
 196 # time-stamp-end: "'; # UTC"
 197 # End: