m4/acl.m4

   1 # acl.m4 - check for access control list (ACL) primitives
   2 # serial 3
   3
   4 # Copyright (C) 2002, 2004-2008 Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Paul Eggert and Jim Meyering.
  10
  11 AC_DEFUN([gl_FUNC_ACL],
  12 [
  13   AC_ARG_ENABLE([acl],
  14     AS_HELP_STRING([--disable-acl], [do not support ACLs]),
  15     , [enable_acl=auto])
  16
  17   LIB_ACL=
  18   use_acl=0
  19   if test "x$enable_acl" != "xno"; then
  20     dnl Prerequisites of lib/acl.c.
  21     AC_CHECK_HEADERS(sys/acl.h)
  22     if test $ac_cv_header_sys_acl_h = yes; then
  23       ac_save_LIBS=$LIBS
  24       AC_CHECK_FUNCS([acl])
  25       use_acl=1
  26       AC_SEARCH_LIBS([acl_trivial], [sec],
  27         [test "$ac_cv_search_acl_trivial" = "none required" ||
  28          LIB_ACL=$ac_cv_search_acl_trivial
  29          AC_CHECK_FUNCS([acl_trivial])],
  30         [AC_CHECK_FUNCS([acl_trivial])
  31          if test $ac_cv_func_acl_trivial != yes; then
  32            AC_SEARCH_LIBS([acl_get_file], [acl],
  33              [test "$ac_cv_search_acl_get_file" = "none required" ||
  34               LIB_ACL=$ac_cv_search_acl_get_file
  35               AC_CHECK_FUNCS(
  36                 [acl_get_file acl_get_fd acl_set_file acl_set_fd \
  37                  acl_free acl_from_mode acl_from_text \
  38                  acl_delete_def_file acl_extended_file])
  39               if test $ac_cv_func_acl_get_file = yes; then
  40                 # If the acl_get_file bug is detected, disable all ACL support.
  41                 gl_ACL_GET_FILE( , [use_acl=0])
  42               fi
  43               if test $use_acl = 1; then
  44                 AC_CHECK_HEADERS([acl/libacl.h])
  45                 if test $ac_cv_func_acl_get_file = yes &&
  46                    test $ac_cv_func_acl_free = yes; then
  47                   AC_REPLACE_FUNCS([acl_entries])
  48                 fi
  49               else
  50                 LIB_ACL=
  51               fi])
  52          fi])
  53       LIBS=$ac_save_LIBS
  54     fi
  55     if test "x$enable_acl$use_acl" = "xyes0"; then
  56       AC_MSG_ERROR([ACLs enabled but support not detected])
  57     fi
  58   fi
  59   AC_SUBST([LIB_ACL])
  60   AC_DEFINE_UNQUOTED([USE_ACL], [$use_acl],
  61     [Define to nonzero if you want access control list support.])
  62
  63   # This is for backwards compatibility; remove this by the end of 2007.
  64   LIB_ACL_TRIVIAL=
  65   AC_SUBST([LIB_ACL_TRIVIAL])
  66 ])
  67
  68 # gl_ACL_GET_FILE(IF-WORKS, IF-NOT)
  69 # -------------------------------------
  70 # If `acl_get_file' works (does not have a particular bug),
  71 # run IF-WORKS, otherwise, IF-NOT.
  72 # This tests for a Darwin 8.7.0 bug, whereby acl_get_file returns NULL,
  73 # but sets errno = ENOENT for an existing file or directory.
  74 AC_DEFUN([gl_ACL_GET_FILE],
  75 [
  76   AC_CACHE_CHECK([for working acl_get_file], gl_cv_func_working_acl_get_file,
  77     [AC_RUN_IFELSE(
  78        [AC_LANG_PROGRAM(
  79           [[#include <sys/types.h>
  80            #include <sys/acl.h>
  81            #include <errno.h>
  82           ]],
  83           [[return !! (!acl_get_file (".", ACL_TYPE_ACCESS)
  84                        && errno == ENOENT);]])],
  85        [gl_cv_func_working_acl_get_file=yes],
  86        [gl_cv_func_working_acl_get_file=no],
  87        [gl_cv_func_working_acl_get_file=cross-compiling])])
  88
  89   AS_IF([test $gl_cv_func_working_acl_get_file = yes], [$1], [$2])
  90 ])