m4/argp.m4

   1 # argp.m4 serial 5
   2 dnl Copyright (C) 2003-2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_ARGP],
   8 [
   9   AC_REQUIRE([AC_C_INLINE])
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11   AC_REQUIRE([gl_GETOPT_SUBSTITUTE])
  12
  13   AC_CHECK_DECL([program_invocation_name],
  14                 [AC_DEFINE(HAVE_DECL_PROGRAM_INVOCATION_NAME, 1,
  15                            [Define if program_invocation_name is declared])],
  16                 [AC_DEFINE(GNULIB_PROGRAM_INVOCATION_NAME, 1,
  17                            [Define to 1 to add extern declaration of program_invocation_name to argp-namefrob.h])],
  18                 [#include <errno.h>])
  19   AC_CHECK_DECL([program_invocation_short_name],
  20                 [AC_DEFINE(HAVE_DECL_PROGRAM_INVOCATION_SHORT_NAME, 1,
  21                            [Define if program_invocation_short_name is declared])],
  22                 [AC_DEFINE(GNULIB_PROGRAM_INVOCATION_SHORT_NAME, 1,
  23                            [Define to 1 to add extern declaration of program_invocation_short_name to argp-namefrob.h])],
  24                 [#include <errno.h>])
  25
  26   # Check if program_invocation_name and program_invocation_short_name
  27   # are defined elsewhere. It is improbable that only one of them will
  28   # be defined and other not, I prefer to stay on the safe side and to
  29   # test each one separately.
  30   AC_MSG_CHECKING(whether program_invocation_name is defined)
  31   AC_TRY_COMPILE([#include <argp.h>],
  32                  [ program_invocation_name = "test"; ],
  33                  [ AC_DEFINE(HAVE_PROGRAM_INVOCATION_NAME,1,
  34                    [Define if program_invocation_name is defined])
  35                    AC_MSG_RESULT(yes)],
  36                  [ AC_MSG_RESULT(no)] )
  37
  38   AC_MSG_CHECKING(whether program_invocation_short_name is defined)
  39   AC_TRY_COMPILE([#include <argp.h>],
  40                  [ program_invocation_short_name = "test"; ],
  41                  [ AC_DEFINE(HAVE_PROGRAM_INVOCATION_SHORT_NAME,1,
  42                    [Define if program_invocation_short_name is defined])
  43                    AC_MSG_RESULT(yes)],
  44                  [ AC_MSG_RESULT(no)] )
  45
  46   AC_CHECK_DECLS_ONCE(
  47      [clearerr_unlocked feof_unlocked ferror_unlocked
  48       fflush_unlocked fgets_unlocked fputc_unlocked fputs_unlocked
  49       fread_unlocked fwrite_unlocked getc_unlocked
  50       getchar_unlocked putc_unlocked putchar_unlocked])
  51   AC_CHECK_FUNCS_ONCE([flockfile funlockfile])
  52   AC_CHECK_HEADERS_ONCE([features.h linewrap.h])
  53 ])