m4/argz.m4

   1 # Portability macros for glibc argz.                    -*- Autoconf -*-
   2 # Written by Gary V. Vaughan <gary@gnu.org>
   3
   4 # Copyright (C) 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 # This file is free software; the Free Software Foundation gives
   7 # unlimited permission to copy and/or distribute it, with or without
   8 # modifications, as long as this notice is preserved.
   9
  10 # serial 4 argz.m4
  11
  12 AC_DEFUN([gl_FUNC_ARGZ],
  13 [gl_PREREQ_ARGZ
  14
  15 AC_CHECK_HEADERS([argz.h], [], [], [AC_INCLUDES_DEFAULT])
  16
  17 AC_CHECK_TYPES([error_t],
  18   [],
  19   [AC_DEFINE([error_t], [int],
  20    [Define to a type to use for `error_t' if it is not otherwise available.])
  21    AC_DEFINE([__error_t_defined], [1], [Define so that glibc/gnulib argp.h
  22     does not typedef error_t.])],
  23   [#if defined(HAVE_ARGZ_H)
  24 #  include <argz.h>
  25 #endif])
  26
  27 ARGZ_H=
  28 AC_CHECK_FUNCS([argz_append argz_create_sep argz_insert argz_next \
  29         argz_stringify], [], [ARGZ_H=argz.h; AC_LIBOBJ([argz])])
  30 AC_SUBST([ARGZ_H])
  31 ])
  32
  33 # Prerequisites of lib/argz.c.
  34 AC_DEFUN([gl_PREREQ_ARGZ], [:])