m4/atanl.m4

   1 # atanl.m4 serial 6
   2 dnl Copyright (C) 2010-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_ATANL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare atanl().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   ATANL_LIBM=
  16   AC_CACHE_CHECK([whether atanl() can be used without linking with libm],
  17     [gl_cv_func_atanl_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double x;]],
  26            [[return atanl (x) > 1;]])],
  27         [gl_cv_func_atanl_no_libm=yes],
  28         [gl_cv_func_atanl_no_libm=no])
  29     ])
  30   if test $gl_cv_func_atanl_no_libm = no; then
  31     AC_CACHE_CHECK([whether atanl() can be used with libm],
  32       [gl_cv_func_atanl_in_libm],
  33       [
  34         save_LIBS="$LIBS"
  35         LIBS="$LIBS -lm"
  36         AC_LINK_IFELSE(
  37           [AC_LANG_PROGRAM(
  38              [[#ifndef __NO_MATH_INLINES
  39                # define __NO_MATH_INLINES 1 /* for glibc */
  40                #endif
  41                #include <math.h>
  42                long double x;]],
  43              [[return atanl (x) > 1;]])],
  44           [gl_cv_func_atanl_in_libm=yes],
  45           [gl_cv_func_atanl_in_libm=no])
  46         LIBS="$save_LIBS"
  47       ])
  48     if test $gl_cv_func_atanl_in_libm = yes; then
  49       ATANL_LIBM=-lm
  50     fi
  51   fi
  52   if test $gl_cv_func_atanl_no_libm = yes \
  53      || test $gl_cv_func_atanl_in_libm = yes; then
  54     dnl Also check whether it's declared.
  55     dnl MacOS X 10.3 has atanl() in libc but doesn't declare it in <math.h>.
  56     AC_CHECK_DECL([atanl], , [HAVE_DECL_ATANL=0], [[#include <math.h>]])
  57   else
  58     HAVE_DECL_ATANL=0
  59     HAVE_ATANL=0
  60     dnl Find libraries needed to link lib/atanl.c.
  61     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  62       AC_REQUIRE([gl_FUNC_ATAN])
  63       ATANL_LIBM="$ATAN_LIBM"
  64     else
  65       AC_REQUIRE([gl_FUNC_ISNANL])
  66       dnl Append $ISNANL_LIBM to ATANL_LIBM, avoiding gratuitous duplicates.
  67       case " $ATANL_LIBM " in
  68         *" $ISNANL_LIBM "*) ;;
  69         *) ATANL_LIBM="$ATANL_LIBM $ISNANL_LIBM" ;;
  70       esac
  71     fi
  72   fi
  73   AC_SUBST([ATANL_LIBM])
  74 ])