m4/cbrtl.m4

   1 # cbrtl.m4 serial 4
   2 dnl Copyright (C) 2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CBRTL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_cbrtl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12   AC_REQUIRE([gl_FUNC_CBRT])
  13
  14   dnl Persuade glibc <math.h> to declare cbrtl().
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl Test whether cbrtl() exists. Assume that cbrtl(), if it exists, is
  18   dnl defined in the same library as cbrt().
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $CBRT_LIBM"
  21   AC_CHECK_FUNCS([cbrtl])
  22   LIBS="$save_LIBS"
  23   if test $ac_cv_func_cbrtl = yes; then
  24     CBRTL_LIBM="$CBRT_LIBM"
  25     dnl Also check whether it's declared.
  26     dnl IRIX 6.5 has cbrtl() in libm but doesn't declare it in <math.h>.
  27     AC_CHECK_DECL([cbrtl], , [HAVE_DECL_CBRTL=0], [[#include <math.h>]])
  28
  29     save_LIBS="$LIBS"
  30     LIBS="$LIBS $CBRTL_LIBM"
  31     gl_FUNC_CBRTL_WORKS
  32     LIBS="$save_LIBS"
  33     case "$gl_cv_func_cbrtl_works" in
  34       *yes) ;;
  35       *) REPLACE_CBRTL=1 ;;
  36     esac
  37
  38     m4_ifdef([gl_FUNC_CBRTL_IEEE], [
  39       if test $gl_cbrtl_required = ieee && test $REPLACE_CBRTL = 0; then
  40         AC_CACHE_CHECK([whether cbrtl works according to ISO C 99 with IEC 60559],
  41           [gl_cv_func_cbrtl_ieee],
  42           [
  43             save_LIBS="$LIBS"
  44             LIBS="$LIBS $CBRTL_LIBM"
  45             AC_RUN_IFELSE(
  46               [AC_LANG_SOURCE([[
  47 #ifndef __NO_MATH_INLINES
  48 # define __NO_MATH_INLINES 1 /* for glibc */
  49 #endif
  50 #include <math.h>
  51 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  52 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  53 static long double dummy (long double x) { return 0; }
  54 int main (int argc, char *argv[])
  55 {
  56   extern
  57   #ifdef __cplusplus
  58   "C"
  59   #endif
  60   long double cbrtl (long double);
  61   long double (*my_cbrtl) (long double) = argc ? cbrtl : dummy;
  62   long double f;
  63   /* Test cbrtl(-0.0).
  64      This test fails on IRIX 6.5.  */
  65   f = my_cbrtl (minus_zerol);
  66   if (!(f == 0.0L) || (signbitl (minus_zerol) && !signbitl (f)))
  67     return 1;
  68   return 0;
  69 }
  70               ]])],
  71               [gl_cv_func_cbrtl_ieee=yes],
  72               [gl_cv_func_cbrtl_ieee=no],
  73               [gl_cv_func_cbrtl_ieee="guessing no"])
  74             LIBS="$save_LIBS"
  75           ])
  76         case "$gl_cv_func_cbrtl_ieee" in
  77           *yes) ;;
  78           *) REPLACE_CBRTL=1 ;;
  79         esac
  80       fi
  81     ])
  82   else
  83     HAVE_CBRTL=0
  84     HAVE_DECL_CBRTL=0
  85   fi
  86   if test $HAVE_CBRTL = 0 || test $REPLACE_CBRTL = 1; then
  87     dnl Find libraries needed to link lib/cbrtl.c.
  88     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  89       CBRTL_LIBM="$CBRT_LIBM"
  90     else
  91       AC_REQUIRE([gl_FUNC_FREXPL])
  92       AC_REQUIRE([gl_FUNC_LDEXPL])
  93       CBRTL_LIBM=
  94       dnl Append $FREXPL_LIBM to CBRTL_LIBM, avoiding gratuitous duplicates.
  95       case " $CBRTL_LIBM " in
  96         *" $FREXPL_LIBM "*) ;;
  97         *) CBRTL_LIBM="$CBRTL_LIBM $FREXPL_LIBM" ;;
  98       esac
  99       dnl Append $LDEXPL_LIBM to CBRTL_LIBM, avoiding gratuitous duplicates.
 100       case " $CBRTL_LIBM " in
 101         *" $LDEXPL_LIBM "*) ;;
 102         *) CBRTL_LIBM="$CBRTL_LIBM $LDEXPL_LIBM" ;;
 103       esac
 104     fi
 105   fi
 106   AC_SUBST([CBRTL_LIBM])
 107 ])
 108
 109 dnl Test whether cbrtl() works.
 110 dnl On OpenBSD 5.1/SPARC, cbrtl(16.0L) is = 1.2599...
 111 AC_DEFUN([gl_FUNC_CBRTL_WORKS],
 112 [
 113   AC_REQUIRE([AC_PROG_CC])
 114   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 115   AC_CACHE_CHECK([whether cbrtl works], [gl_cv_func_cbrtl_works],
 116     [
 117       AC_RUN_IFELSE(
 118         [AC_LANG_SOURCE([[
 119 #include <math.h>
 120 extern
 121 #ifdef __cplusplus
 122 "C"
 123 #endif
 124 long double cbrtl (long double);
 125 volatile long double x;
 126 long double y;
 127 int main ()
 128 {
 129   x = 16.0L;
 130   y = cbrtl (x);
 131   if (y < 2.0L)
 132     return 1;
 133   return 0;
 134 }
 135 ]])],
 136         [gl_cv_func_cbrtl_works=yes],
 137         [gl_cv_func_cbrtl_works=no],
 138         [case "$host_os" in
 139            openbsd*) gl_cv_func_cbrtl_works="guessing no";;
 140            *)        gl_cv_func_cbrtl_works="guessing yes";;
 141          esac
 142         ])
 143     ])
 144 ])