m4/ceill.m4

   1 # ceill.m4 serial 10
   2 dnl Copyright (C) 2007, 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CEILL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_ceill_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   dnl Persuade glibc <math.h> to declare ceill().
  12   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  13   dnl Test whether ceill() is declared.
  14   AC_CHECK_DECLS([ceill], , , [#include <math.h>])
  15   if test "$ac_cv_have_decl_ceill" = yes; then
  16     dnl Test whether ceill() can be used without libm.
  17     gl_FUNC_CEILL_LIBS
  18     if test "$CEILL_LIBM" = "?"; then
  19       dnl Sun C 5.0 on Solaris declares ceill() and has it in the system-wide
  20       dnl libm.so, but not in the libm.so that the compiler uses.
  21       REPLACE_CEILL=1
  22     fi
  23     m4_ifdef([gl_FUNC_CEILL_IEEE], [
  24       if test $gl_ceill_required = ieee && test $REPLACE_CEILL = 0; then
  25         AC_CACHE_CHECK([whether ceill works according to ISO C 99 with IEC 60559],
  26           [gl_cv_func_ceill_ieee],
  27           [
  28             save_LIBS="$LIBS"
  29             LIBS="$LIBS $CEILL_LIBM"
  30             AC_RUN_IFELSE(
  31               [AC_LANG_SOURCE([[
  32 #ifndef __NO_MATH_INLINES
  33 # define __NO_MATH_INLINES 1 /* for glibc */
  34 #endif
  35 #include <math.h>
  36 ]gl_LONG_DOUBLE_MINUS_ZERO_CODE[
  37 ]gl_LONG_DOUBLE_SIGNBIT_CODE[
  38 static long double dummy (long double f) { return 0; }
  39 int main (int argc, char *argv[])
  40 {
  41   long double (*my_ceill) (long double) = argc ? ceill : dummy;
  42   /* Test whether ceill (-0.3L) is -0.0L.  */
  43   if (signbitl (minus_zerol) && !signbitl (my_ceill (-0.3L)))
  44     return 1;
  45   return 0;
  46 }
  47               ]])],
  48               [gl_cv_func_ceill_ieee=yes],
  49               [gl_cv_func_ceill_ieee=no],
  50               [gl_cv_func_ceill_ieee="guessing no"])
  51             LIBS="$save_LIBS"
  52           ])
  53         case "$gl_cv_func_ceill_ieee" in
  54           *yes) ;;
  55           *) REPLACE_CEILL=1 ;;
  56         esac
  57       fi
  58     ])
  59   else
  60     HAVE_DECL_CEILL=0
  61   fi
  62   if test $HAVE_DECL_CEILL = 0 || test $REPLACE_CEILL = 1; then
  63     dnl No libraries are needed to link lib/ceill.c.
  64     CEILL_LIBM=
  65   fi
  66   AC_SUBST([CEILL_LIBM])
  67 ])
  68
  69 # Determines the libraries needed to get the ceill() function.
  70 # Sets CEILL_LIBM.
  71 AC_DEFUN([gl_FUNC_CEILL_LIBS],
  72 [
  73   gl_CACHE_VAL_SILENT([gl_cv_func_ceill_libm], [
  74     gl_cv_func_ceill_libm=?
  75     AC_LINK_IFELSE(
  76       [AC_LANG_PROGRAM(
  77          [[#ifndef __NO_MATH_INLINES
  78            # define __NO_MATH_INLINES 1 /* for glibc */
  79            #endif
  80            #include <math.h>
  81            long double x;]],
  82          [[x = ceill(x);]])],
  83       [gl_cv_func_ceill_libm=])
  84     if test "$gl_cv_func_ceill_libm" = "?"; then
  85       save_LIBS="$LIBS"
  86       LIBS="$LIBS -lm"
  87       AC_LINK_IFELSE(
  88         [AC_LANG_PROGRAM(
  89            [[#ifndef __NO_MATH_INLINES
  90              # define __NO_MATH_INLINES 1 /* for glibc */
  91              #endif
  92              #include <math.h>
  93              long double x;]],
  94            [[x = ceill(x);]])],
  95         [gl_cv_func_ceill_libm="-lm"])
  96       LIBS="$save_LIBS"
  97     fi
  98   ])
  99   CEILL_LIBM="$gl_cv_func_ceill_libm"
 100 ])