m4/chdir-long.m4

   1 #serial 7
   2
   3 # Use Gnulib's robust chdir function.
   4 # It can handle arbitrarily long directory names, which means
   5 # that when it is given the name of an existing directory, it
   6 # never fails with ENAMETOOLONG.
   7 # Arrange to compile chdir-long.c only on systems that define PATH_MAX.
   8
   9 dnl Copyright (C) 2004, 2005 Free Software Foundation, Inc.
  10 dnl This file is free software; the Free Software Foundation
  11 dnl gives unlimited permission to copy and/or distribute it,
  12 dnl with or without modifications, as long as this notice is preserved.
  13
  14 # Written by Jim Meyering.
  15
  16 AC_DEFUN([gl_FUNC_CHDIR_LONG],
  17 [
  18   AC_LIBSOURCES([chdir-long.c, chdir-long.h])
  19   AC_CACHE_CHECK([whether this system has an arbitrary file name length limit],
  20     gl_have_arbitrary_file_name_length_limit,
  21     [AC_EGREP_CPP([have_arbitrary_file_name_length_limit],
  22                   [#include <unistd.h>
  23 #include <limits.h>
  24 #if defined PATH_MAX || defined MAXPATHLEN
  25 have_arbitrary_file_name_length_limit
  26 #endif],
  27     gl_have_arbitrary_file_name_length_limit=yes,
  28     gl_have_arbitrary_file_name_length_limit=no)])
  29
  30   if test $gl_have_arbitrary_file_name_length_limit = yes; then
  31     AC_LIBOBJ([chdir-long])
  32     gl_PREREQ_CHDIR_LONG
  33   fi
  34 ])
  35
  36 AC_DEFUN([gl_PREREQ_CHDIR_LONG],
  37 [
  38   AM_STDBOOL_H
  39   gl_FUNC_MEMPCPY
  40   gl_FUNC_OPENAT
  41   gl_FUNC_MEMRCHR
  42 ])