m4/close.m4

   1 # close.m4 serial 7
   2 dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_CLOSE],
   8 [
   9   m4_ifdef([gl_PREREQ_SYS_H_WINSOCK2], [
  10     gl_PREREQ_SYS_H_WINSOCK2
  11     if test $UNISTD_H_HAVE_WINSOCK2_H = 1; then
  12       dnl Even if the 'socket' module is not used here, another part of the
  13       dnl application may use it and pass file descriptors that refer to
  14       dnl sockets to the close() function. So enable the support for sockets.
  15       gl_REPLACE_CLOSE
  16     fi
  17   ])
  18   dnl Replace close() for supporting the gnulib-defined fchdir() function,
  19   dnl to keep fchdir's bookkeeping up-to-date.
  20   m4_ifdef([gl_FUNC_FCHDIR], [
  21     if test $REPLACE_CLOSE = 0; then
  22       gl_TEST_FCHDIR
  23       if test $HAVE_FCHDIR = 0; then
  24         gl_REPLACE_CLOSE
  25       fi
  26     fi
  27   ])
  28 ])
  29
  30 AC_DEFUN([gl_REPLACE_CLOSE],
  31 [
  32   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  33   REPLACE_CLOSE=1
  34   AC_LIBOBJ([close])
  35   m4_ifdef([gl_REPLACE_FCLOSE], [gl_REPLACE_FCLOSE])
  36 ])