m4/dirfd.m4

   1 #serial 12   -*- Autoconf -*-
   2
   3 dnl Find out how to get the file descriptor associated with an open DIR*.
   4
   5 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   6 # Foundation, Inc.
   7 # This file is free software; the Free Software Foundation
   8 # gives unlimited permission to copy and/or distribute it,
   9 # with or without modifications, as long as this notice is preserved.
  10
  11 dnl From Jim Meyering
  12
  13 AC_DEFUN([gl_FUNC_DIRFD],
  14 [
  15   AC_LIBSOURCES([dirfd.c, dirfd.h])
  16
  17   dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
  18   AC_REQUIRE([AC_PROG_CPP])
  19   AC_REQUIRE([AC_PROG_EGREP])
  20   AC_CHECK_HEADERS_ONCE([dirent.h])dnl
  21
  22   dirfd_headers='
  23 #if HAVE_DIRENT_H
  24 # include <dirent.h>
  25 #else
  26 # define dirent direct
  27 # include <ndir.h>
  28 #endif
  29 '
  30   AC_CHECK_FUNCS(dirfd)
  31   AC_CHECK_DECLS([dirfd], , , $dirfd_headers)
  32
  33   AC_CACHE_CHECK([whether dirfd is a macro],
  34     gl_cv_func_dirfd_macro,
  35     [AC_EGREP_CPP([dirent_header_defines_dirfd], [$dirfd_headers
  36 #ifdef dirfd
  37  dirent_header_defines_dirfd
  38 #endif],
  39        gl_cv_func_dirfd_macro=yes,
  40        gl_cv_func_dirfd_macro=no)])
  41
  42   # Use the replacement only if we have no function, macro,
  43   # or declaration with that name.
  44   if test $ac_cv_func_dirfd,$ac_cv_have_decl_dirfd,$gl_cv_func_dirfd_macro \
  45       = no,no,no; then
  46     AC_REPLACE_FUNCS([dirfd])
  47     AC_CACHE_CHECK(
  48               [how to get the file descriptor associated with an open DIR*],
  49                    gl_cv_sys_dir_fd_member_name,
  50       [
  51         dirfd_save_CFLAGS=$CFLAGS
  52         for ac_expr in d_fd dd_fd; do
  53
  54           CFLAGS="$CFLAGS -DDIR_FD_MEMBER_NAME=$ac_expr"
  55           AC_TRY_COMPILE(
  56             [$dirfd_headers
  57             ],
  58             [DIR *dir_p = opendir("."); (void) dir_p->DIR_FD_MEMBER_NAME;],
  59             dir_fd_found=yes
  60           )
  61           CFLAGS=$dirfd_save_CFLAGS
  62           test "$dir_fd_found" = yes && break
  63         done
  64         test "$dir_fd_found" = yes || ac_expr=no_such_member
  65
  66         gl_cv_sys_dir_fd_member_name=$ac_expr
  67       ]
  68     )
  69     if test $gl_cv_sys_dir_fd_member_name != no_such_member; then
  70       AC_DEFINE_UNQUOTED(DIR_FD_MEMBER_NAME,
  71         $gl_cv_sys_dir_fd_member_name,
  72         [the name of the file descriptor member of DIR])
  73     fi
  74     AH_VERBATIM(DIR_TO_FD,
  75                 [#ifdef DIR_FD_MEMBER_NAME
  76 # define DIR_TO_FD(Dir_p) ((Dir_p)->DIR_FD_MEMBER_NAME)
  77 #else
  78 # define DIR_TO_FD(Dir_p) -1
  79 #endif
  80 ])
  81   fi
  82 ])