m4/expm1l.m4

   1 # expm1l.m4 serial 1
   2 dnl Copyright (C) 2010-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_EXPM1L],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  11
  12   dnl Persuade glibc <math.h> to declare expm1l().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   EXPM1L_LIBM=
  16   AC_CACHE_CHECK([whether expm1l() can be used without linking with libm],
  17     [gl_cv_func_expm1l_no_libm],
  18     [
  19       AC_LINK_IFELSE(
  20         [AC_LANG_PROGRAM(
  21            [[#ifndef __NO_MATH_INLINES
  22              # define __NO_MATH_INLINES 1 /* for glibc */
  23              #endif
  24              #include <math.h>
  25              long double (*funcptr) (long double) = expm1l;
  26              long double x;]],
  27            [[return funcptr (x) > 0.5
  28                     || expm1l (x) > 0.5;]])],
  29         [gl_cv_func_expm1l_no_libm=yes],
  30         [gl_cv_func_expm1l_no_libm=no])
  31     ])
  32   if test $gl_cv_func_expm1l_no_libm = no; then
  33     AC_CACHE_CHECK([whether expm1l() can be used with libm],
  34       [gl_cv_func_expm1l_in_libm],
  35       [
  36         save_LIBS="$LIBS"
  37         LIBS="$LIBS -lm"
  38         AC_LINK_IFELSE(
  39           [AC_LANG_PROGRAM(
  40              [[#ifndef __NO_MATH_INLINES
  41                # define __NO_MATH_INLINES 1 /* for glibc */
  42                #endif
  43                #include <math.h>
  44                long double (*funcptr) (long double) = expm1l;
  45                long double x;]],
  46              [[return funcptr (x) > 0.5
  47                       || expm1l (x) > 0.5;]])],
  48           [gl_cv_func_expm1l_in_libm=yes],
  49           [gl_cv_func_expm1l_in_libm=no])
  50         LIBS="$save_LIBS"
  51       ])
  52     if test $gl_cv_func_expm1l_in_libm = yes; then
  53       EXPM1L_LIBM=-lm
  54     fi
  55   fi
  56   if test $gl_cv_func_expm1l_no_libm = no \
  57      && test $gl_cv_func_expm1l_in_libm = no; then
  58     HAVE_EXPM1L=0
  59     dnl Find libraries needed to link lib/expm1l.c.
  60     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  61       AC_REQUIRE([gl_FUNC_EXPM1])
  62       EXPM1L_LIBM="$EXPM1_LIBM"
  63     else
  64       AC_REQUIRE([gl_FUNC_ISNANL])
  65       AC_REQUIRE([gl_FUNC_EXPL])
  66       AC_REQUIRE([gl_FUNC_ROUNDL])
  67       AC_REQUIRE([gl_FUNC_LDEXPL])
  68       EXPM1L_LIBM=
  69       dnl Append $ISNANL_LIBM to EXPM1L_LIBM, avoiding gratuitous duplicates.
  70       case " $EXPM1L_LIBM " in
  71         *" $ISNANL_LIBM "*) ;;
  72         *) EXPM1L_LIBM="$EXPM1L_LIBM $ISNANL_LIBM" ;;
  73       esac
  74       dnl Append $EXPL_LIBM to EXPM1L_LIBM, avoiding gratuitous duplicates.
  75       case " $EXPM1L_LIBM " in
  76         *" $EXPL_LIBM "*) ;;
  77         *) EXPM1L_LIBM="$EXPM1L_LIBM $EXPL_LIBM" ;;
  78       esac
  79       dnl Append $ROUNDL_LIBM to EXPM1L_LIBM, avoiding gratuitous duplicates.
  80       case " $EXPM1L_LIBM " in
  81         *" $ROUNDL_LIBM "*) ;;
  82         *) EXPM1L_LIBM="$EXPM1L_LIBM $ROUNDL_LIBM" ;;
  83       esac
  84       dnl Append $LDEXPL_LIBM to EXPM1L_LIBM, avoiding gratuitous duplicates.
  85       case " $EXPM1L_LIBM " in
  86         *" $LDEXPL_LIBM "*) ;;
  87         *) EXPM1L_LIBM="$EXPM1L_LIBM $LDEXPL_LIBM" ;;
  88       esac
  89     fi
  90   fi
  91   AC_SUBST([EXPM1L_LIBM])
  92 ])