m4/fchdir.m4

   1 # fchdir.m4 serial 17
   2 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  12
  13   AC_CHECK_DECLS_ONCE([fchdir])
  14   if test $ac_cv_have_decl_fchdir = no; then
  15     HAVE_DECL_FCHDIR=0
  16   fi
  17
  18   AC_REQUIRE([gl_TEST_FCHDIR])
  19   if test $HAVE_FCHDIR = 0; then
  20     AC_LIBOBJ([fchdir])
  21     gl_PREREQ_FCHDIR
  22     AC_DEFINE([REPLACE_FCHDIR], [1],
  23       [Define to 1 if gnulib's fchdir() replacement is used.])
  24     dnl We must also replace anything that can manipulate a directory fd,
  25     dnl to keep our bookkeeping up-to-date.  We don't have to replace
  26     dnl fstatat, since no platform has fstatat but lacks fchdir.
  27     REPLACE_OPENDIR=1
  28     REPLACE_CLOSEDIR=1
  29     REPLACE_DUP=1
  30     AC_CACHE_CHECK([whether open can visit directories],
  31       [gl_cv_func_open_directory_works],
  32       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  33 ]], [return open(".", O_RDONLY) < 0;])],
  34         [gl_cv_func_open_directory_works=yes],
  35         [gl_cv_func_open_directory_works=no],
  36         [gl_cv_func_open_directory_works="guessing no"])])
  37     if test "$gl_cv_func_open_directory_works" != yes; then
  38       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  39 work around the inability to open a directory.])
  40       REPLACE_FSTAT=1
  41     fi
  42   fi
  43 ])
  44
  45 # Determine whether to use the overrides in lib/fchdir.c.
  46 AC_DEFUN([gl_TEST_FCHDIR],
  47 [
  48   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  49   AC_CHECK_FUNCS_ONCE([fchdir])
  50   if test $ac_cv_func_fchdir = no; then
  51     HAVE_FCHDIR=0
  52   fi
  53 ])
  54
  55 # Prerequisites of lib/fchdir.c.
  56 AC_DEFUN([gl_PREREQ_FCHDIR], [:])