m4/fchdir.m4

   1 # fchdir.m4 serial 20
   2 dnl Copyright (C) 2006-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11
  12   AC_CHECK_DECLS_ONCE([fchdir])
  13   if test $ac_cv_have_decl_fchdir = no; then
  14     HAVE_DECL_FCHDIR=0
  15   fi
  16
  17   AC_REQUIRE([gl_TEST_FCHDIR])
  18   if test $HAVE_FCHDIR = 0; then
  19     AC_LIBOBJ([fchdir])
  20     gl_PREREQ_FCHDIR
  21     AC_DEFINE([REPLACE_FCHDIR], [1],
  22       [Define to 1 if gnulib's fchdir() replacement is used.])
  23     dnl We must also replace anything that can manipulate a directory fd,
  24     dnl to keep our bookkeeping up-to-date.  We don't have to replace
  25     dnl fstatat, since no platform has fstatat but lacks fchdir.
  26     AC_CACHE_CHECK([whether open can visit directories],
  27       [gl_cv_func_open_directory_works],
  28       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  29 ]], [return open(".", O_RDONLY) < 0;])],
  30         [gl_cv_func_open_directory_works=yes],
  31         [gl_cv_func_open_directory_works=no],
  32         [gl_cv_func_open_directory_works="guessing no"])])
  33     if test "$gl_cv_func_open_directory_works" != yes; then
  34       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  35 work around the inability to open a directory.])
  36     fi
  37   fi
  38 ])
  39
  40 # Determine whether to use the overrides in lib/fchdir.c.
  41 AC_DEFUN([gl_TEST_FCHDIR],
  42 [
  43   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  44   AC_CHECK_FUNCS_ONCE([fchdir])
  45   if test $ac_cv_func_fchdir = no; then
  46     HAVE_FCHDIR=0
  47   fi
  48 ])
  49
  50 # Prerequisites of lib/fchdir.c.
  51 AC_DEFUN([gl_PREREQ_FCHDIR], [:])