m4/fchdir.m4

   1 # fchdir.m4 serial 9
   2 dnl Copyright (C) 2006-2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_CHECK_FUNCS_ONCE([fchdir])
  12   if test $ac_cv_func_fchdir = no; then
  13     REPLACE_FCHDIR=1
  14     AC_LIBOBJ([fchdir])
  15     gl_PREREQ_FCHDIR
  16     AC_DEFINE([FCHDIR_REPLACEMENT], [1],
  17       [Define if gnulib's fchdir() replacement is used.])
  18     gl_REPLACE_OPEN
  19     gl_REPLACE_CLOSE
  20     gl_REPLACE_DUP2
  21     dnl dup3 is already unconditionally replaced
  22     gl_REPLACE_DIRENT_H
  23     AC_CACHE_CHECK([whether open can visit directories],
  24       [gl_cv_func_open_directory_works],
  25       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  26 ]], [return open(".", O_RDONLY);])],
  27         [gl_cv_func_open_directory_works=yes],
  28         [gl_cv_func_open_directory_works=no],
  29         [gl_cv_func_open_directory_works="guessing no"])])
  30     if test "$gl_cv_func_open_directory_works" != yes; then
  31       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  32 work around the inability to open a directory.])
  33     fi
  34   fi
  35 ])
  36
  37 # Prerequisites of lib/fchdir.c.
  38 AC_DEFUN([gl_PREREQ_FCHDIR], [:])