m4/fchdir.m4

   1 # fchdir.m4 serial 8
   2 dnl Copyright (C) 2006-2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_CHECK_FUNCS_ONCE([fchdir])
  12   if test $ac_cv_func_fchdir = no; then
  13     REPLACE_FCHDIR=1
  14     AC_LIBOBJ([fchdir])
  15     gl_PREREQ_FCHDIR
  16     AC_DEFINE([FCHDIR_REPLACEMENT], [1],
  17       [Define if gnulib's fchdir() replacement is used.])
  18     gl_REPLACE_OPEN
  19     gl_REPLACE_CLOSE
  20     gl_REPLACE_DIRENT_H
  21     AC_CACHE_CHECK([whether open can visit directories],
  22       [gl_cv_func_open_directory_works],
  23       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  24 ]], [return open(".", O_RDONLY);])],
  25         [gl_cv_func_open_directory_works=yes],
  26         [gl_cv_func_open_directory_works=no],
  27         [gl_cv_func_open_directory_works="guessing no"])])
  28     if test "$gl_cv_func_open_directory_works" != yes; then
  29       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  30 work around the inability to open a directory.])
  31     fi
  32   fi
  33 ])
  34
  35 # Prerequisites of lib/fchdir.c.
  36 AC_DEFUN([gl_PREREQ_FCHDIR], [:])