m4/fchdir.m4

   1 # fchdir.m4 serial 9
   2 dnl Copyright (C) 2006-2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  12   AC_CHECK_FUNCS_ONCE([fchdir])
  13   if test $ac_cv_func_fchdir = no; then
  14     REPLACE_FCHDIR=1
  15     AC_LIBOBJ([fchdir])
  16     gl_PREREQ_FCHDIR
  17     AC_DEFINE([REPLACE_FCHDIR], [1],
  18       [Define to 1 if gnulib's fchdir() replacement is used.])
  19     REPLACE_FSTAT=1
  20     gl_REPLACE_OPEN
  21     gl_REPLACE_CLOSE
  22     gl_REPLACE_DUP2
  23     dnl dup3 is already unconditionally replaced
  24     gl_REPLACE_DIRENT_H
  25     AC_CACHE_CHECK([whether open can visit directories],
  26       [gl_cv_func_open_directory_works],
  27       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  28 ]], [return open(".", O_RDONLY);])],
  29         [gl_cv_func_open_directory_works=yes],
  30         [gl_cv_func_open_directory_works=no],
  31         [gl_cv_func_open_directory_works="guessing no"])])
  32     if test "$gl_cv_func_open_directory_works" != yes; then
  33       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  34 work around the inability to open a directory.])
  35     fi
  36   fi
  37 ])
  38
  39 # Prerequisites of lib/fchdir.c.
  40 AC_DEFUN([gl_PREREQ_FCHDIR], [:])