m4/fdopendir.m4

   1 # serial 9
   2 # See if we need to provide fdopendir.
   3
   4 dnl Copyright (C) 2009-2012 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_FDOPENDIR],
  12 [
  13   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  14
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl FreeBSD 7.3 has the function, but failed to declare it.
  18   AC_CHECK_DECLS([fdopendir], [], [HAVE_DECL_FDOPENDIR=0], [[
  19 #include <dirent.h>
  20     ]])
  21   AC_CHECK_FUNCS_ONCE([fdopendir])
  22   if test $ac_cv_func_fdopendir = no; then
  23     HAVE_FDOPENDIR=0
  24   else
  25     AC_CACHE_CHECK([whether fdopendir works],
  26       [gl_cv_func_fdopendir_works],
  27       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  28 #include <dirent.h>
  29 #include <fcntl.h>
  30 #include <unistd.h>
  31 #if !HAVE_DECL_FDOPENDIR
  32 extern
  33 # ifdef __cplusplus
  34 "C"
  35 # endif
  36 DIR *fdopendir (int);
  37 #endif
  38 ]], [int result = 0;
  39      int fd = open ("conftest.c", O_RDONLY);
  40      if (fd < 0) result |= 1;
  41      if (fdopendir (fd)) result |= 2;
  42      if (close (fd)) result |= 4;
  43      return result;])],
  44          [gl_cv_func_fdopendir_works=yes],
  45          [gl_cv_func_fdopendir_works=no],
  46          [gl_cv_func_fdopendir_works="guessing no"])])
  47     if test "$gl_cv_func_fdopendir_works" != yes; then
  48       REPLACE_FDOPENDIR=1
  49     fi
  50   fi
  51 ])