m4/fdopendir.m4

   1 # serial 8
   2 # See if we need to provide fdopendir.
   3
   4 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_FDOPENDIR],
  12 [
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14   dnl FreeBSD 7.3 has the function, but failed to declare it.
  15   AC_CHECK_DECLS([fdopendir], [], [HAVE_DECL_FDOPENDIR=0], [[
  16 #include <dirent.h>
  17     ]])
  18   AC_CHECK_FUNCS_ONCE([fdopendir])
  19   if test $ac_cv_func_fdopendir = no; then
  20     HAVE_FDOPENDIR=0
  21   else
  22     AC_CACHE_CHECK([whether fdopendir works],
  23       [gl_cv_func_fdopendir_works],
  24       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  25 #include <dirent.h>
  26 #include <fcntl.h>
  27 #include <unistd.h>
  28 #if !HAVE_DECL_FDOPENDIR
  29 extern
  30 # ifdef __cplusplus
  31 "C"
  32 # endif
  33 DIR *fdopendir (int);
  34 #endif
  35 ]], [int result = 0;
  36      int fd = open ("conftest.c", O_RDONLY);
  37      if (fd < 0) result |= 1;
  38      if (fdopendir (fd)) result |= 2;
  39      if (close (fd)) result |= 4;
  40      return result;])],
  41          [gl_cv_func_fdopendir_works=yes],
  42          [gl_cv_func_fdopendir_works=no],
  43          [gl_cv_func_fdopendir_works="guessing no"])])
  44     if test "$gl_cv_func_fdopendir_works" != yes; then
  45       REPLACE_FDOPENDIR=1
  46     fi
  47   fi
  48 ])