m4/fdopendir.m4

   1 # serial 6
   2 # See if we need to provide fdopendir.
   3
   4 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_FDOPENDIR],
  12 [
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14   dnl FreeBSD 7.3 has the function, but failed to declare it.
  15   AC_CHECK_DECLS([fdopendir], [], [HAVE_DECL_FDOPENDIR=0], [[
  16 #include <dirent.h>
  17     ]])
  18   AC_CHECK_FUNCS_ONCE([fdopendir])
  19   if test $ac_cv_func_fdopendir = no; then
  20     AC_LIBOBJ([openat-proc])
  21     AC_LIBOBJ([fdopendir])
  22     HAVE_FDOPENDIR=0
  23   else
  24     AC_CACHE_CHECK([whether fdopendir works],
  25       [gl_cv_func_fdopendir_works],
  26       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  27 #include <dirent.h>
  28 #include <fcntl.h>
  29 #include <unistd.h>
  30 #if !HAVE_DECL_FDOPENDIR
  31 extern DIR *fdopendir (int);
  32 #endif
  33 ]], [int result = 0;
  34      int fd = open ("conftest.c", O_RDONLY);
  35      if (fd < 0) result |= 1;
  36      if (fdopendir (fd)) result |= 2;
  37      if (close (fd)) result |= 4;
  38      return result;])],
  39          [gl_cv_func_fdopendir_works=yes],
  40          [gl_cv_func_fdopendir_works=no],
  41          [gl_cv_func_fdopendir_works="guessing no"])])
  42     if test "$gl_cv_func_fdopendir_works" != yes; then
  43       REPLACE_FDOPENDIR=1
  44       AC_LIBOBJ([fdopendir])
  45     fi
  46   fi
  47 ])