m4/fprintf-posix.m4

   1 # fprintf-posix.m4 serial 8
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE])
  13   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  20   AC_REQUIRE([gl_PRINTF_ENOMEM])
  21   gl_cv_func_fprintf_posix=no
  22   case "$gl_cv_func_printf_sizes_c99" in
  23     *yes)
  24       case "$gl_cv_func_printf_long_double" in
  25         *yes)
  26           case "$gl_cv_func_printf_infinite" in
  27             *yes)
  28               case "$gl_cv_func_printf_infinite_long_double" in
  29                 *yes)
  30                   case "$gl_cv_func_printf_directive_a" in
  31                     *yes)
  32                       case "$gl_cv_func_printf_directive_f" in
  33                         *yes)
  34                           case "$gl_cv_func_printf_directive_n" in
  35                             *yes)
  36                               case "$gl_cv_func_printf_positions" in
  37                                 *yes)
  38                                   case "$gl_cv_func_printf_flag_grouping" in
  39                                     *yes)
  40                                       case "$gl_cv_func_printf_flag_zero" in
  41                                         *yes)
  42                                           case "$gl_cv_func_printf_enomem" in
  43                                             *yes)
  44                                               # fprintf exists and is already
  45                                               # POSIX compliant.
  46                                               gl_cv_func_fprintf_posix=yes
  47                                               ;;
  48                                           esac
  49                                           ;;
  50                                       esac
  51                                       ;;
  52                                   esac
  53                                   ;;
  54                               esac
  55                               ;;
  56                           esac
  57                           ;;
  58                       esac
  59                       ;;
  60                   esac
  61                   ;;
  62               esac
  63               ;;
  64           esac
  65           ;;
  66       esac
  67       ;;
  68   esac
  69   if test $gl_cv_func_fprintf_posix = no; then
  70     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  71     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
  72     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
  73     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  74     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  75     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  76     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  77     gl_PREREQ_VASNPRINTF_ENOMEM
  78     gl_REPLACE_VASNPRINTF
  79     gl_REPLACE_FPRINTF
  80   fi
  81 ])
  82
  83 AC_DEFUN([gl_REPLACE_FPRINTF],
  84 [
  85   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  86   AC_LIBOBJ([fprintf])
  87   REPLACE_FPRINTF=1
  88   gl_PREREQ_FPRINTF
  89 ])
  90
  91 AC_DEFUN([gl_PREREQ_FPRINTF], [:])