m4/frexp.m4

   1 # frexp.m4 serial 9
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FREXP],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   AC_REQUIRE([gl_CHECK_FREXP_NO_LIBM])
  11   FREXP_LIBM=
  12   if test $gl_cv_func_frexp_no_libm = no; then
  13     AC_CACHE_CHECK([whether frexp() can be used with libm],
  14       [gl_cv_func_frexp_in_libm],
  15       [
  16         save_LIBS="$LIBS"
  17         LIBS="$LIBS -lm"
  18         AC_LINK_IFELSE(
  19           [AC_LANG_PROGRAM(
  20              [[#include <math.h>
  21                double x;]],
  22              [[int e; return frexp (x, &e) > 0;]])],
  23           [gl_cv_func_frexp_in_libm=yes],
  24           [gl_cv_func_frexp_in_libm=no])
  25         LIBS="$save_LIBS"
  26       ])
  27     if test $gl_cv_func_frexp_in_libm = yes; then
  28       FREXP_LIBM=-lm
  29     fi
  30   fi
  31   if test $gl_cv_func_frexp_no_libm = yes \
  32      || test $gl_cv_func_frexp_in_libm = yes; then
  33     save_LIBS="$LIBS"
  34     LIBS="$LIBS $FREXP_LIBM"
  35     gl_FUNC_FREXP_WORKS
  36     LIBS="$save_LIBS"
  37     case "$gl_cv_func_frexp_works" in
  38       *yes) gl_func_frexp=yes ;;
  39       *)    gl_func_frexp=no; REPLACE_FREXP=1; FREXP_LIBM= ;;
  40     esac
  41   else
  42     gl_func_frexp=no
  43   fi
  44   if test $gl_func_frexp = yes; then
  45     AC_DEFINE([HAVE_FREXP], [1],
  46       [Define if the frexp() function is available and works.])
  47   else
  48     AC_LIBOBJ([frexp])
  49   fi
  50   AC_SUBST([FREXP_LIBM])
  51 ])
  52
  53 AC_DEFUN([gl_FUNC_FREXP_NO_LIBM],
  54 [
  55   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  56   AC_REQUIRE([gl_CHECK_FREXP_NO_LIBM])
  57   if test $gl_cv_func_frexp_no_libm = yes; then
  58     gl_FUNC_FREXP_WORKS
  59     case "$gl_cv_func_frexp_works" in
  60       *yes) gl_func_frexp_no_libm=yes ;;
  61       *)    gl_func_frexp_no_libm=no; REPLACE_FREXP=1 ;;
  62     esac
  63   else
  64     gl_func_frexp_no_libm=no
  65     dnl Set REPLACE_FREXP here because the system may have frexp in libm.
  66     REPLACE_FREXP=1
  67   fi
  68   if test $gl_func_frexp_no_libm = yes; then
  69     AC_DEFINE([HAVE_FREXP_IN_LIBC], [1],
  70       [Define if the frexp() function is available in libc.])
  71   else
  72     AC_LIBOBJ([frexp])
  73   fi
  74 ])
  75
  76 dnl Test whether frexp() can be used without linking with libm.
  77 dnl Set gl_cv_func_frexp_no_libm to 'yes' or 'no' accordingly.
  78 AC_DEFUN([gl_CHECK_FREXP_NO_LIBM],
  79 [
  80   AC_CACHE_CHECK([whether frexp() can be used without linking with libm],
  81     [gl_cv_func_frexp_no_libm],
  82     [
  83       AC_LINK_IFELSE(
  84         [AC_LANG_PROGRAM(
  85            [[#include <math.h>
  86              double x;]],
  87            [[int e; return frexp (x, &e) > 0;]])],
  88         [gl_cv_func_frexp_no_libm=yes],
  89         [gl_cv_func_frexp_no_libm=no])
  90     ])
  91 ])
  92
  93 dnl Test whether frexp() works also on denormalized numbers (this fails e.g. on
  94 dnl NetBSD 3.0), on infinite numbers (this fails e.g. on IRIX 6.5 and mingw),
  95 dnl and on negative zero (this fails e.g. on NetBSD 4.99).
  96 AC_DEFUN([gl_FUNC_FREXP_WORKS],
  97 [
  98   AC_REQUIRE([AC_PROG_CC])
  99   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 100   AC_CACHE_CHECK([whether frexp works], [gl_cv_func_frexp_works],
 101     [
 102       AC_TRY_RUN([
 103 #include <float.h>
 104 #include <math.h>
 105 #include <string.h>
 106 int main()
 107 {
 108   int i;
 109   volatile double x;
 110 /* HP cc on HP-UX 10.20 has a bug with the constant expression -0.0.
 111    So we use -zero instead.  */
 112   double zero = 0.0;
 113   /* Test on denormalized numbers.  */
 114   for (i = 1, x = 1.0; i >= DBL_MIN_EXP; i--, x *= 0.5)
 115     ;
 116   if (x > 0.0)
 117     {
 118       int exp;
 119       double y = frexp (x, &exp);
 120       /* On machines with IEEE754 arithmetic: x = 1.11254e-308, exp = -1022.
 121          On NetBSD: y = 0.75. Correct: y = 0.5.  */
 122       if (y != 0.5)
 123         return 1;
 124     }
 125   /* Test on infinite numbers.  */
 126   x = 1.0 / 0.0;
 127   {
 128     int exp;
 129     double y = frexp (x, &exp);
 130     if (y != x)
 131       return 1;
 132   }
 133   /* Test on negative zero.  */
 134   x = -zero;
 135   {
 136     int exp;
 137     double y = frexp (x, &exp);
 138     if (memcmp (&y, &x, sizeof x))
 139       return 1;
 140   }
 141   return 0;
 142 }], [gl_cv_func_frexp_works=yes], [gl_cv_func_frexp_works=no],
 143       [case "$host_os" in
 144          netbsd* | irix* | mingw*) gl_cv_func_frexp_works="guessing no";;
 145          *)                        gl_cv_func_frexp_works="guessing yes";;
 146        esac
 147       ])
 148     ])
 149 ])