m4/frexp.m4

   1 # frexp.m4 serial 3
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FREXP],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   FREXP_LIBM=
  11   AC_CACHE_CHECK([whether frexp() can be used without linking with libm],
  12     [gl_cv_func_frexp_no_libm],
  13     [
  14       AC_TRY_LINK([#include <math.h>
  15                    double x;],
  16                   [int e; return frexp (x, &e) > 0;],
  17         [gl_cv_func_frexp_no_libm=yes],
  18         [gl_cv_func_frexp_no_libm=no])
  19     ])
  20   if test $gl_cv_func_frexp_no_libm = no; then
  21     AC_CACHE_CHECK([whether frexp() can be used with libm],
  22       [gl_cv_func_frexp_in_libm],
  23       [
  24         save_LIBS="$LIBS"
  25         LIBS="$LIBS -lm"
  26         AC_TRY_LINK([#include <math.h>
  27                      double x;],
  28                     [int e; return frexp (x, &e) > 0;],
  29           [gl_cv_func_frexp_in_libm=yes],
  30           [gl_cv_func_frexp_in_libm=no])
  31         LIBS="$save_LIBS"
  32       ])
  33     if test $gl_cv_func_frexp_in_libm = yes; then
  34       FREXP_LIBM=-lm
  35     fi
  36   fi
  37   if test $gl_cv_func_frexp_no_libm = yes \
  38      || test $gl_cv_func_frexp_in_libm = yes; then
  39     save_LIBS="$LIBS"
  40     LIBS="$LIBS $FREXP_LIBM"
  41     gl_FUNC_FREXP_WORKS
  42     LIBS="$save_LIBS"
  43     case "$gl_cv_func_frexp_works" in
  44       *yes) gl_func_frexp=yes ;;
  45       *)    gl_func_frexp=no; REPLACE_FREXP=1; FREXP_LIBM= ;;
  46     esac
  47   else
  48     gl_func_frexp=no
  49   fi
  50   if test $gl_func_frexp = yes; then
  51     AC_DEFINE([HAVE_FREXP], 1,
  52       [Define if the frexp() function is available and works.])
  53   else
  54     AC_LIBOBJ([frexp])
  55   fi
  56   AC_SUBST([FREXP_LIBM])
  57 ])
  58
  59 dnl Test whether frexp() works also on denormalized numbers (this fails e.g. on
  60 dnl NetBSD 3.0) and on infinite numbers (this fails e.g. on IRIX 6.5).
  61 AC_DEFUN([gl_FUNC_FREXP_WORKS],
  62 [
  63   AC_REQUIRE([AC_PROG_CC])
  64   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  65   AC_CACHE_CHECK([whether frexp works], [gl_cv_func_frexp_works],
  66     [
  67       AC_TRY_RUN([
  68 #include <float.h>
  69 #include <math.h>
  70 int main()
  71 {
  72   int i;
  73   volatile double x;
  74   /* Test on denormalized numbers.  */
  75   for (i = 1, x = 1.0; i >= DBL_MIN_EXP; i--, x *= 0.5)
  76     ;
  77   if (x > 0.0)
  78     {
  79       int exp;
  80       double y = frexp (x, &exp);
  81       /* On machines with IEEE754 arithmetic: x = 1.11254e-308, exp = -1022.
  82          On NetBSD: y = 0.75. Correct: y = 0.5.  */
  83       if (y != 0.5)
  84         return 1;
  85     }
  86   /* Test on infinite numbers.  */
  87   x = 1.0 / 0.0;
  88   {
  89     int exp;
  90     double y = frexp (x, &exp);
  91     if (y != x)
  92       return 1;
  93   }
  94   return 0;
  95 }], [gl_cv_func_frexp_works=yes], [gl_cv_func_frexp_works=no],
  96       [case "$host_os" in
  97          netbsd* | irix*) gl_cv_func_frexp_works="guessing no";;
  98          *)               gl_cv_func_frexp_works="guessing yes";;
  99        esac
 100       ])
 101     ])
 102 ])