m4/frexpl.m4

   1 # frexpl.m4 serial 2
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FREXPL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   FREXPL_LIBM=
  11   AC_CACHE_CHECK([whether frexpl() can be used without linking with libm],
  12     [gl_cv_func_frexpl_no_libm],
  13     [
  14       AC_TRY_LINK([#include <math.h>
  15                    long double x;],
  16                   [int e; return frexpl (x, &e) > 0;],
  17         [gl_cv_func_frexpl_no_libm=yes],
  18         [gl_cv_func_frexpl_no_libm=no])
  19     ])
  20   if test $gl_cv_func_frexpl_no_libm = no; then
  21     AC_CACHE_CHECK([whether frexpl() can be used with libm],
  22       [gl_cv_func_frexpl_in_libm],
  23       [
  24         save_LIBS="$LIBS"
  25         LIBS="$LIBS -lm"
  26         AC_TRY_LINK([#include <math.h>
  27                      long double x;],
  28                     [int e; return frexpl (x, &e) > 0;],
  29           [gl_cv_func_frexpl_in_libm=yes],
  30           [gl_cv_func_frexpl_in_libm=no])
  31         LIBS="$save_LIBS"
  32       ])
  33     if test $gl_cv_func_frexpl_in_libm = yes; then
  34       FREXPL_LIBM=-lm
  35     fi
  36   fi
  37   if test $gl_cv_func_frexpl_no_libm = yes \
  38      || test $gl_cv_func_frexpl_in_libm = yes; then
  39     save_LIBS="$LIBS"
  40     LIBS="$LIBS $FREXPL_LIBM"
  41     gl_FUNC_FREXPL_WORKS
  42     LIBS="$save_LIBS"
  43     case "$gl_cv_func_frexpl_works" in
  44       *yes) gl_func_frexpl=yes ;;
  45       *)    gl_func_frexpl=no; REPLACE_FREXPL=1; FREXPL_LIBM= ;;
  46     esac
  47   else
  48     gl_func_frexpl=no
  49   fi
  50   if test $gl_func_frexpl = yes; then
  51     AC_DEFINE([HAVE_FREXPL], 1,
  52       [Define if the frexpl() function is available.])
  53     dnl Also check whether it's declared.
  54     dnl MacOS X 10.3 has frexpl() in libc but doesn't declare it in <math.h>.
  55     AC_CHECK_DECL([frexpl], , [HAVE_DECL_FREXPL=0], [#include <math.h>])
  56   else
  57     HAVE_DECL_FREXPL=0
  58     AC_LIBOBJ([frexpl])
  59   fi
  60   AC_SUBST([FREXPL_LIBM])
  61 ])
  62
  63 dnl Test whether frexpl() works on finite numbers (this fails on AIX 5.1) and
  64 dnl also on infinite numbers (this fails e.g. on IRIX 6.5).
  65 AC_DEFUN([gl_FUNC_FREXPL_WORKS],
  66 [
  67   AC_REQUIRE([AC_PROG_CC])
  68   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  69   AC_CACHE_CHECK([whether frexpl works], [gl_cv_func_frexpl_works],
  70     [
  71       AC_TRY_RUN([
  72 #include <math.h>
  73 extern long double frexpl (long double, int *);
  74 int main()
  75 {
  76   volatile long double x;
  77   /* Test on finite numbers.  */
  78   {
  79     int exp = -9999;
  80     x = 16.0L;
  81     frexpl (x, &exp);
  82     if (exp != 5)
  83       return 1;
  84   }
  85   /* Test on infinite numbers.  */
  86   {
  87     x = 1.0L / 0.0L;
  88     int exp;
  89     long double y = frexpl (x, &exp);
  90     if (y != x)
  91       return 1;
  92   }
  93   return 0;
  94 }], [gl_cv_func_frexpl_works=yes], [gl_cv_func_frexpl_works=no],
  95       [case "$host_os" in
  96          aix* | irix*) gl_cv_func_frexpl_works="guessing no";;
  97          *)            gl_cv_func_frexpl_works="guessing yes";;
  98        esac
  99       ])
 100     ])
 101 ])