m4/fseeko.m4

   1 # fseeko.m4 serial 12
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([gl_HAVE_FSEEKO])
  11   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  12
  13   AC_CHECK_DECLS_ONCE([fseeko])
  14   if test $ac_cv_have_decl_fseeko = no; then
  15     HAVE_DECL_FSEEKO=0
  16   fi
  17
  18   if test $gl_cv_func_fseeko = no; then
  19     HAVE_FSEEKO=0
  20     gl_REPLACE_FSEEKO
  21   else
  22     if test $gl_cv_var_stdin_large_offset = no; then
  23       gl_REPLACE_FSEEKO
  24     fi
  25   fi
  26   m4_ifdef([gl_FUNC_FFLUSH_STDIN], [
  27     gl_FUNC_FFLUSH_STDIN
  28     if test $gl_cv_func_fflush_stdin = no; then
  29       gl_REPLACE_FSEEKO
  30     fi
  31   ])
  32 ])
  33
  34 dnl Tests whether fseeko is available.
  35 dnl Result is gl_cv_func_fseeko.
  36 AC_DEFUN([gl_HAVE_FSEEKO],
  37 [
  38   AC_REQUIRE([AC_PROG_CC])
  39
  40   dnl Persuade glibc <stdio.h> to declare fseeko().
  41   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  42
  43   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  44     [
  45       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  46 ]], [fseeko (stdin, 0, 0);])],
  47         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  48     ])
  49 ])
  50
  51 AC_DEFUN([gl_REPLACE_FSEEKO],
  52 [
  53   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  54   AC_REQUIRE([gl_HAVE_FSEEKO])
  55   if test $gl_cv_func_fseeko = yes; then
  56     REPLACE_FSEEKO=1
  57   fi
  58   AC_LIBOBJ([fseeko])
  59   dnl If we are also using the fseek module, then fseek needs replacing, too.
  60   m4_ifdef([gl_REPLACE_FSEEK], [gl_REPLACE_FSEEK])
  61 ])
  62
  63 dnl Code shared by fseeko and ftello.  Determine if large files are supported,
  64 dnl but stdin does not start as a large file by default.
  65 AC_DEFUN([gl_STDIN_LARGE_OFFSET],
  66   [
  67     AC_CACHE_CHECK([whether stdin defaults to large file offsets],
  68       [gl_cv_var_stdin_large_offset],
  69       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]],
  70 [[#if defined __SL64 && defined __SCLE /* cygwin */
  71   /* Cygwin 1.5.24 and earlier fail to put stdin in 64-bit mode, making
  72      fseeko/ftello needlessly fail.  This bug was fixed in 1.5.25, and
  73      it is easier to do a version check than building a runtime test.  */
  74 # include <cygwin/version.h>
  75 # if CYGWIN_VERSION_DLL_COMBINED < CYGWIN_VERSION_DLL_MAKE_COMBINED (1005, 25)
  76   choke me
  77 # endif
  78 #endif]])],
  79         [gl_cv_var_stdin_large_offset=yes],
  80         [gl_cv_var_stdin_large_offset=no])])
  81 ])