m4/fseeko.m4

   1 # fseeko.m4 serial 15
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  11   AC_REQUIRE([AC_PROG_CC])
  12
  13   dnl Persuade glibc <stdio.h> to declare fseeko().
  14   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  15
  16   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  17     [
  18       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  19 ]], [fseeko (stdin, 0, 0);])],
  20         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  21     ])
  22
  23   AC_CHECK_DECLS_ONCE([fseeko])
  24   if test $ac_cv_have_decl_fseeko = no; then
  25     HAVE_DECL_FSEEKO=0
  26   fi
  27
  28   if test $gl_cv_func_fseeko = no; then
  29     HAVE_FSEEKO=0
  30   else
  31     if test $gl_cv_var_stdin_large_offset = no; then
  32       REPLACE_FSEEKO=1
  33     fi
  34     m4_ifdef([gl_FUNC_FFLUSH_STDIN], [
  35       gl_FUNC_FFLUSH_STDIN
  36       if test $gl_cv_func_fflush_stdin = no; then
  37         REPLACE_FSEEKO=1
  38       fi
  39     ])
  40   fi
  41 ])
  42
  43 dnl Code shared by fseeko and ftello.  Determine if large files are supported,
  44 dnl but stdin does not start as a large file by default.
  45 AC_DEFUN([gl_STDIN_LARGE_OFFSET],
  46   [
  47     AC_CACHE_CHECK([whether stdin defaults to large file offsets],
  48       [gl_cv_var_stdin_large_offset],
  49       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]],
  50 [[#if defined __SL64 && defined __SCLE /* cygwin */
  51   /* Cygwin 1.5.24 and earlier fail to put stdin in 64-bit mode, making
  52      fseeko/ftello needlessly fail.  This bug was fixed in 1.5.25, and
  53      it is easier to do a version check than building a runtime test.  */
  54 # include <cygwin/version.h>
  55 # if CYGWIN_VERSION_DLL_COMBINED < CYGWIN_VERSION_DLL_MAKE_COMBINED (1005, 25)
  56   choke me
  57 # endif
  58 #endif]])],
  59         [gl_cv_var_stdin_large_offset=yes],
  60         [gl_cv_var_stdin_large_offset=no])])
  61 ])