m4/fseeko.m4

   1 # fseeko.m4 serial 8
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([AC_PROG_CC])
  11   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  12
  13   dnl Persuade glibc <stdio.h> to declare fseeko().
  14   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  15
  16   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  17     [
  18       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  19 ]], [fseeko (stdin, 0, 0);])],
  20         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  21     ])
  22   if test $gl_cv_func_fseeko = no; then
  23     HAVE_FSEEKO=0
  24   else
  25     if test $gl_cv_var_stdin_large_offset = no; then
  26       REPLACE_FSEEKO=1
  27     fi
  28   fi
  29   if test $HAVE_FSEEKO = 0 || test $REPLACE_FSEEKO = 1; then
  30     gl_REPLACE_FSEEKO
  31   fi
  32 ])
  33
  34 AC_DEFUN([gl_REPLACE_FSEEKO],
  35 [
  36   AC_LIBOBJ([fseeko])
  37   dnl If we are also using the fseek module, then fseek needs replacing, too.
  38   m4_ifdef([gl_REPLACE_FSEEK], [gl_REPLACE_FSEEK])
  39 ])