m4/getaddrinfo.m4

   1 # getaddrinfo.m4 serial 18
   2 dnl Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_GETADDRINFO],
   8 [
   9   AC_REQUIRE([gl_HEADER_SYS_SOCKET])dnl for HAVE_SYS_SOCKET_H, HAVE_WINSOCK2_H
  10   AC_REQUIRE([gl_HEADER_NETDB])dnl for HAVE_NETDB_H
  11   AC_MSG_NOTICE([checking how to do getaddrinfo, freeaddrinfo and getnameinfo])
  12
  13   AC_SEARCH_LIBS(getaddrinfo, [nsl socket])
  14   AC_CACHE_CHECK([for getaddrinfo], [gl_cv_func_getaddrinfo], [
  15     AC_TRY_LINK([
  16 #include <sys/types.h>
  17 #ifdef HAVE_SYS_SOCKET_H
  18 #include <sys/socket.h>
  19 #endif
  20 #ifdef HAVE_NETDB_H
  21 #include <netdb.h>
  22 #endif
  23 #include <stddef.h>
  24 ], [getaddrinfo("", "", NULL, NULL);],
  25       [gl_cv_func_getaddrinfo=yes],
  26       [gl_cv_func_getaddrinfo=no])])
  27   if test $gl_cv_func_getaddrinfo = no; then
  28     AC_CACHE_CHECK(for getaddrinfo in ws2tcpip.h and -lws2_32,
  29                    gl_cv_w32_getaddrinfo, [
  30       gl_cv_w32_getaddrinfo=no
  31       am_save_LIBS="$LIBS"
  32       LIBS="$LIBS -lws2_32"
  33       AC_TRY_LINK([
  34 #ifdef HAVE_WS2TCPIP_H
  35 #include <ws2tcpip.h>
  36 #endif
  37 #include <stddef.h>
  38 ], [getaddrinfo(NULL, NULL, NULL, NULL);], gl_cv_w32_getaddrinfo=yes)
  39       LIBS="$am_save_LIBS"
  40     ])
  41     if test "$gl_cv_w32_getaddrinfo" = "yes"; then
  42       LIBS="$LIBS -lws2_32"
  43     else
  44       AC_LIBOBJ(getaddrinfo)
  45     fi
  46   fi
  47
  48   # We can't use AC_REPLACE_FUNCS here because gai_strerror may be an
  49   # inline function declared in ws2tcpip.h, so we need to get that
  50   # header included somehow.
  51   AC_CACHE_CHECK([for gai_strerror (possibly via ws2tcpip.h)],
  52     gl_cv_func_gai_strerror, [
  53       AC_TRY_LINK([
  54 #include <sys/types.h>
  55 #ifdef HAVE_SYS_SOCKET_H
  56 #include <sys/socket.h>
  57 #endif
  58 #ifdef HAVE_NETDB_H
  59 #include <netdb.h>
  60 #endif
  61 #ifdef HAVE_WS2TCPIP_H
  62 #include <ws2tcpip.h>
  63 #endif
  64 #include <stddef.h>
  65 ], [gai_strerror (NULL);],
  66         [gl_cv_func_gai_strerror=yes],
  67         [gl_cv_func_gai_strerror=no])])
  68   if test $gl_cv_func_gai_strerror = no; then
  69     AC_LIBOBJ(gai_strerror)
  70   fi
  71
  72   gl_PREREQ_GETADDRINFO
  73 ])
  74
  75 # Prerequisites of lib/netdb.in.h and lib/getaddrinfo.c.
  76 AC_DEFUN([gl_PREREQ_GETADDRINFO], [
  77   AC_REQUIRE([gl_NETDB_H_DEFAULTS])
  78   AC_REQUIRE([gl_HEADER_SYS_SOCKET])dnl for HAVE_SYS_SOCKET_H, HAVE_WINSOCK2_H
  79   AC_REQUIRE([gl_HOSTENT]) dnl for HOSTENT_LIB
  80   AC_REQUIRE([gl_SERVENT]) dnl for SERVENT_LIB
  81   LIBS="$LIBS $HOSTENT_LIB $SERVENT_LIB"
  82   AC_REQUIRE([AC_C_RESTRICT])
  83   AC_REQUIRE([gl_SOCKET_FAMILIES])
  84   AC_REQUIRE([gl_HEADER_SYS_SOCKET])
  85   AC_REQUIRE([AC_C_INLINE])
  86   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  87
  88   dnl Including sys/socket.h is wrong for Windows, but Windows does not
  89   dnl have sa_len so the result is correct anyway.
  90   AC_CHECK_MEMBERS([struct sockaddr.sa_len], , , [#include <sys/socket.h>])
  91
  92   AC_CHECK_HEADERS_ONCE(netinet/in.h)
  93
  94   AC_CHECK_DECLS([getaddrinfo, freeaddrinfo, gai_strerror, getnameinfo],,,[
  95   /* sys/types.h is not needed according to POSIX, but the
  96      sys/socket.h in i386-unknown-freebsd4.10 and
  97      powerpc-apple-darwin5.5 required it. */
  98 #include <sys/types.h>
  99 #ifdef HAVE_SYS_SOCKET_H
 100 #include <sys/socket.h>
 101 #endif
 102 #ifdef HAVE_NETDB_H
 103 #include <netdb.h>
 104 #endif
 105 #ifdef HAVE_WS2TCPIP_H
 106 #include <ws2tcpip.h>
 107 #endif
 108 ])
 109   if test $ac_cv_have_decl_getaddrinfo = no; then
 110     HAVE_DECL_GETADDRINFO=0
 111   fi
 112   if test $ac_cv_have_decl_freeaddrinfo = no; then
 113     HAVE_DECL_FREEADDRINFO=0
 114   fi
 115   if test $ac_cv_have_decl_gai_strerror = no; then
 116     HAVE_DECL_GAI_STRERROR=0
 117   fi
 118   if test $ac_cv_have_decl_getnameinfo = no; then
 119     HAVE_DECL_GETNAMEINFO=0
 120   fi
 121
 122   AC_CHECK_TYPES([struct addrinfo],,,[
 123 #include <sys/types.h>
 124 #ifdef HAVE_SYS_SOCKET_H
 125 #include <sys/socket.h>
 126 #endif
 127 #ifdef HAVE_NETDB_H
 128 #include <netdb.h>
 129 #endif
 130 #ifdef HAVE_WS2TCPIP_H
 131 #include <ws2tcpip.h>
 132 #endif
 133 ])
 134   if test $ac_cv_type_struct_addrinfo = no; then
 135     HAVE_STRUCT_ADDRINFO=0
 136   fi
 137 ])