m4/getcwd.m4

   1 # getcwd.m4 - check for working getcwd that is compatible with glibc
   2
   3 # Copyright (C) 2001, 2003, 2004, 2005 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Paul Eggert.
   9
  10 AC_DEFUN([gl_FUNC_GETCWD_NULL],
  11   [
  12    AC_LIBSOURCES([getcwd.c, getcwd.h])
  13
  14    AC_CACHE_CHECK([whether getcwd (NULL, 0) allocates memory for result],
  15      [gl_cv_func_getcwd_null],
  16      [AC_TRY_RUN(
  17         [
  18 #        include <stdlib.h>
  19 #        include <unistd.h>
  20 #        ifndef getcwd
  21          char *getcwd ();
  22 #        endif
  23          int
  24          main ()
  25          {
  26            if (chdir ("/") != 0)
  27              exit (1);
  28            else
  29              {
  30                char *f = getcwd (NULL, 0);
  31                exit (! (f && f[0] == '/' && !f[1]));
  32              }
  33          }],
  34         [gl_cv_func_getcwd_null=yes],
  35         [gl_cv_func_getcwd_null=no],
  36         [gl_cv_func_getcwd_null=no])])
  37 ])
  38
  39 AC_DEFUN([gl_FUNC_GETCWD],
  40 [
  41   AC_REQUIRE([gl_FUNC_GETCWD_NULL])
  42
  43   case $gl_cv_func_getcwd_null in
  44   yes) gl_FUNC_GETCWD_PATH_MAX;;
  45   esac
  46
  47   case $gl_cv_func_getcwd_null,$gl_cv_func_getcwd_path_max in
  48   yes,yes) ;;
  49   *)
  50     AC_LIBOBJ([getcwd])
  51     AC_DEFINE([__GETCWD_PREFIX], [[rpl_]],
  52       [Define to rpl_ if the getcwd replacement function should be used.])
  53     gl_PREREQ_GETCWD;;
  54   esac
  55 ])
  56
  57 # Prerequisites of lib/getcwd.c.
  58 AC_DEFUN([gl_PREREQ_GETCWD],
  59 [
  60   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  61   AC_REQUIRE([AC_HEADER_DIRENT])
  62   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_DIRENT_D_INO])
  63   :
  64 ])