m4/getcwd.m4

   1 # getcwd.m4 - check for working getcwd that is compatible with glibc
   2
   3 # Copyright (C) 2001, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Paul Eggert.
   9
  10 AC_DEFUN([gl_FUNC_GETCWD_NULL],
  11   [
  12    AC_LIBSOURCES([getcwd.c, getcwd.h])
  13
  14    AC_CACHE_CHECK([whether getcwd (NULL, 0) allocates memory for result],
  15      [gl_cv_func_getcwd_null],
  16      [AC_TRY_RUN(
  17         [
  18 #        include <stdlib.h>
  19 #        include <unistd.h>
  20 #        ifndef getcwd
  21          char *getcwd ();
  22 #        endif
  23          int
  24          main ()
  25          {
  26            if (chdir ("/") != 0)
  27              exit (1);
  28            else
  29              {
  30                char *f = getcwd (NULL, 0);
  31                exit (! (f && f[0] == '/' && !f[1]));
  32              }
  33          }],
  34         [gl_cv_func_getcwd_null=yes],
  35         [gl_cv_func_getcwd_null=no],
  36         [gl_cv_func_getcwd_null=no])])
  37 ])
  38
  39 AC_DEFUN([gl_FUNC_GETCWD],
  40 [
  41   AC_REQUIRE([gl_FUNC_GETCWD_NULL])
  42
  43   gl_abort_bug=no
  44   case $gl_cv_func_getcwd_null in
  45   yes)
  46     gl_FUNC_GETCWD_PATH_MAX
  47     gl_FUNC_GETCWD_ABORT_BUG([gl_abort_bug=yes]);;
  48   esac
  49
  50   case $gl_cv_func_getcwd_null,$gl_cv_func_getcwd_path_max,$gl_abort_bug in
  51   yes,yes,no) ;;
  52   *)
  53     AC_LIBOBJ([getcwd])
  54     AC_DEFINE([__GETCWD_PREFIX], [[rpl_]],
  55       [Define to rpl_ if the getcwd replacement function should be used.])
  56     gl_PREREQ_GETCWD;;
  57   esac
  58 ])
  59
  60 # Prerequisites of lib/getcwd.c.
  61 AC_DEFUN([gl_PREREQ_GETCWD],
  62 [
  63   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  64   AC_REQUIRE([AC_HEADER_DIRENT])
  65   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_DIRENT_D_INO])
  66   :
  67 ])