m4/getcwd.m4

   1 # getcwd.m4 - check whether getcwd (NULL, 0) allocates memory for result
   2
   3 # Copyright 2001 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software Foundation,
  17 # Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.  */
  18
  19 # Written by Paul Eggert.
  20
  21 AC_DEFUN([AC_FUNC_GETCWD_NULL],
  22   [
  23    AC_CHECK_HEADERS_ONCE(stdlib.h unistd.h)
  24    AC_CACHE_CHECK([whether getcwd (NULL, 0) allocates memory for result],
  25      [ac_cv_func_getcwd_null],
  26      [AC_TRY_RUN(
  27         [
  28 #        ifdef HAVE_STDLIB_H
  29 #         include <stdlib.h>
  30 #        endif
  31 #        ifdef HAVE_UNISTD_H
  32 #         include <unistd.h>
  33 #        endif
  34 #        ifndef getcwd
  35          char *getcwd ();
  36 #        endif
  37          int
  38          main ()
  39          {
  40            if (chdir ("/") != 0)
  41              exit (1);
  42            else
  43              {
  44                char *f = getcwd (NULL, 0);
  45                exit (! (f && f[0] == '/' && !f[1]));
  46              }
  47          }],
  48         [ac_cv_func_getcwd_null=yes],
  49         [ac_cv_func_getcwd_null=no],
  50         [ac_cv_func_getcwd_null=no])])
  51    if test $ac_cv_func_getcwd_null = yes; then
  52      AC_DEFINE(HAVE_GETCWD_NULL, 1,
  53                [Define if getcwd (NULL, 0) allocates memory for result.])
  54    fi])