m4/getcwd.m4

   1 # getcwd.m4 - check for working getcwd that is compatible with glibc
   2
   3 # Copyright (C) 2001, 2003, 2004 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software Foundation,
  17 # Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19 # Written by Paul Eggert.
  20
  21 AC_DEFUN([gl_FUNC_GETCWD_NULL],
  22   [
  23    AC_CHECK_HEADERS_ONCE(unistd.h)
  24    AC_CACHE_CHECK([whether getcwd (NULL, 0) allocates memory for result],
  25      [gl_cv_func_getcwd_null],
  26      [AC_TRY_RUN(
  27         [
  28 #        include <stdlib.h>
  29 #        ifdef HAVE_UNISTD_H
  30 #         include <unistd.h>
  31 #        endif
  32 #        ifndef getcwd
  33          char *getcwd ();
  34 #        endif
  35          int
  36          main ()
  37          {
  38            if (chdir ("/") != 0)
  39              exit (1);
  40            else
  41              {
  42                char *f = getcwd (NULL, 0);
  43                exit (! (f && f[0] == '/' && !f[1]));
  44              }
  45          }],
  46         [gl_cv_func_getcwd_null=yes],
  47         [gl_cv_func_getcwd_null=no],
  48         [gl_cv_func_getcwd_null=no])])
  49 ])
  50
  51 AC_DEFUN([gl_FUNC_GETCWD],
  52 [
  53   AC_REQUIRE([gl_FUNC_GETCWD_NULL])
  54
  55   case $gl_cv_func_getcwd_null in
  56   yes) gl_FUNC_GETCWD_PATH_MAX;;
  57   esac
  58
  59   case $gl_cv_func_getcwd_null,$gl_cv_func_getcwd_path_max in
  60   yes,yes) ;;
  61   *)
  62     AC_LIBOBJ([getcwd])
  63     AC_DEFINE([__GETCWD_PREFIX], [[rpl_]],
  64       [Define to rpl_ if the getcwd replacement function should be used.])
  65     gl_PREREQ_GETCWD;;
  66   esac
  67 ])
  68
  69 # Prerequisites of lib/getcwd.c.
  70 AC_DEFUN([gl_PREREQ_GETCWD],
  71 [
  72   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  73   AC_REQUIRE([AC_HEADER_DIRENT])
  74   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_DIRENT_D_INO])
  75   AC_CHECK_HEADERS_ONCE(fcntl.h)
  76   :
  77 ])