m4/getdate.m4

   1 # getdate.m4 serial 8
   2 dnl Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_C_COMPOUND_LITERALS],
   8 [
   9   AC_CACHE_CHECK([for compound literals], gl_cv_compound_literals,
  10   [AC_TRY_COMPILE([struct s { int i, j; }; struct s s = (struct s) { 1, 2 };],
  11     [struct s t = (struct s) { 3, 4 };],
  12     gl_cv_compound_literals=yes,
  13     gl_cv_compound_literals=no)])
  14   if test $gl_cv_compound_literals = yes; then
  15     AC_DEFINE(HAVE_COMPOUND_LITERALS, 1,
  16       [Define if you have compound literals.])
  17   fi
  18 ])
  19
  20 AC_DEFUN([gl_GETDATE],
  21 [
  22   AC_LIBSOURCES([getdate.h, getdate.y])
  23   AC_LIBOBJ([getdate])
  24
  25   dnl Prerequisites of lib/getdate.h.
  26   AC_REQUIRE([AM_STDBOOL_H])
  27   AC_REQUIRE([gl_TIMESPEC])
  28
  29   dnl Prerequisites of lib/getdate.y.
  30   AC_REQUIRE([gl_BISON])
  31   AC_REQUIRE([gl_C_COMPOUND_LITERALS])
  32   AC_REQUIRE([AC_HEADER_STDC])
  33   AC_CHECK_FUNCS_ONCE(isascii)
  34   AC_STRUCT_TIMEZONE
  35   AC_REQUIRE([gl_CLOCK_TIME])
  36   AC_REQUIRE([gl_TM_GMTOFF])
  37 ])