m4/getgroups.m4

   1 # serial 16
   2
   3 dnl From Jim Meyering.
   4 dnl A wrapper around AC_FUNC_GETGROUPS.
   5
   6 # Copyright (C) 1996-1997, 1999-2004, 2008-2011 Free Software Foundation, Inc.
   7 #
   8 # This file is free software; the Free Software Foundation
   9 # gives unlimited permission to copy and/or distribute it,
  10 # with or without modifications, as long as this notice is preserved.
  11
  12 AC_DEFUN([gl_FUNC_GETGROUPS],
  13 [
  14   AC_REQUIRE([AC_FUNC_GETGROUPS])
  15   AC_REQUIRE([AC_TYPE_GETGROUPS])
  16   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  17   if test "$ac_cv_func_getgroups" != yes; then
  18     HAVE_GETGROUPS=0
  19   elif test "$ac_cv_func_getgroups_works.$ac_cv_type_getgroups" != yes.gid_t
  20   then
  21     REPLACE_GETGROUPS=1
  22     AC_DEFINE([GETGROUPS_ZERO_BUG], [1], [Define this to 1 if
  23       getgroups(0,NULL) does not return the number of groups.])
  24   else
  25     dnl Detect FreeBSD bug; POSIX requires getgroups(-1,ptr) to fail.
  26     AC_CACHE_CHECK([whether getgroups handles negative values],
  27       [gl_cv_func_getgroups_works],
  28       [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
  29         [[int size = getgroups (0, 0);
  30           gid_t *list = malloc (size * sizeof *list);
  31           return getgroups (-1, list) != -1;]])],
  32         [gl_cv_func_getgroups_works=yes],
  33         [gl_cv_func_getgroups_works=no],
  34         [gl_cv_func_getgroups_works="guessing no"])])
  35     if test "$gl_cv_func_getgroups_works" != yes; then
  36       REPLACE_GETGROUPS=1
  37     fi
  38   fi
  39   test -n "$GETGROUPS_LIB" && LIBS="$GETGROUPS_LIB $LIBS"
  40 ])