m4/gethostname.m4

   1 # gethostname.m4 serial 12
   2 dnl Copyright (C) 2002, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # Ensure
   8 # - the gethostname() function,
   9 # - the HOST_NAME_MAX macro in <limits.h>.
  10 AC_DEFUN([gl_FUNC_GETHOSTNAME],
  11 [
  12   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  13   gl_PREREQ_SYS_H_WINSOCK2
  14
  15   dnl Where is gethostname() defined?
  16   dnl - On native Windows, it is in ws2_32.dll.
  17   dnl - Otherwise it is in libc.
  18   GETHOSTNAME_LIB=
  19   AC_CHECK_FUNCS([gethostname], , [
  20     AC_CACHE_CHECK([for gethostname in winsock2.h and -lws2_32],
  21       [gl_cv_w32_gethostname],
  22       [gl_cv_w32_gethostname=no
  23        gl_save_LIBS="$LIBS"
  24        LIBS="$LIBS -lws2_32"
  25        AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  26 #ifdef HAVE_WINSOCK2_H
  27 #include <winsock2.h>
  28 #endif
  29 #include <stddef.h>
  30 ]], [[gethostname(NULL, 0);]])], [gl_cv_w32_gethostname=yes])
  31        LIBS="$gl_save_LIBS"
  32       ])
  33     if test "$gl_cv_w32_gethostname" = "yes"; then
  34       GETHOSTNAME_LIB="-lws2_32"
  35     fi
  36   ])
  37   AC_SUBST([GETHOSTNAME_LIB])
  38
  39   if test "$ac_cv_func_gethostname" = no; then
  40     HAVE_GETHOSTNAME=0
  41   fi
  42
  43   dnl Also provide HOST_NAME_MAX when <limits.h> lacks it.
  44   dnl - On most Unix systems, use MAXHOSTNAMELEN from <sys/param.h> instead.
  45   dnl - On Solaris, Cygwin, BeOS, use MAXHOSTNAMELEN from <netdb.h> instead.
  46   dnl - On mingw, use 256, because
  47   dnl   <http://msdn.microsoft.com/en-us/library/ms738527.aspx> says:
  48   dnl   "if a buffer of 256 bytes is passed in the name parameter and
  49   dnl    the namelen parameter is set to 256, the buffer size will always
  50   dnl    be adequate."
  51   dnl With this, there is no need to use sysconf (_SC_HOST_NAME_MAX), which
  52   dnl is not a compile-time constant.
  53   dnl We cannot override <limits.h> using the usual technique, because
  54   dnl gl_CHECK_NEXT_HEADERS does not work for <limits.h>. Therefore retrieve
  55   dnl the value of HOST_NAME_MAX at configure time.
  56   AC_CHECK_HEADERS_ONCE([sys/param.h])
  57   AC_CHECK_HEADERS_ONCE([sys/socket.h])
  58   AC_CHECK_HEADERS_ONCE([netdb.h])
  59   AC_CACHE_CHECK([for HOST_NAME_MAX], [gl_cv_decl_HOST_NAME_MAX], [
  60     gl_cv_decl_HOST_NAME_MAX=
  61     AC_EGREP_CPP([lucky], [
  62 #include <limits.h>
  63 #ifdef HOST_NAME_MAX
  64 lucky
  65 #endif
  66       ], [gl_cv_decl_HOST_NAME_MAX=yes])
  67     if test -z "$gl_cv_decl_HOST_NAME_MAX"; then
  68       dnl It's not defined in <limits.h>. Substitute it.
  69       if test "$gl_cv_w32_gethostname" = yes; then
  70         dnl mingw.
  71         gl_cv_decl_HOST_NAME_MAX=256
  72       else
  73         _AC_COMPUTE_INT([MAXHOSTNAMELEN], [gl_cv_decl_HOST_NAME_MAX], [
  74 #include <sys/types.h>
  75 #if HAVE_SYS_PARAM_H
  76 # include <sys/param.h>
  77 #endif
  78 #if HAVE_SYS_SOCKET_H
  79 # include <sys/socket.h>
  80 #endif
  81 #if HAVE_NETDB_H
  82 # include <netdb.h>
  83 #endif
  84 ],
  85           [dnl The system does not define MAXHOSTNAMELEN in any of the common
  86            dnl headers. Use a safe fallback.
  87            gl_cv_decl_HOST_NAME_MAX=256
  88           ])
  89       fi
  90     fi
  91   ])
  92   if test "$gl_cv_decl_HOST_NAME_MAX" != yes; then
  93     AC_DEFINE_UNQUOTED([HOST_NAME_MAX], [$gl_cv_decl_HOST_NAME_MAX],
  94       [Define HOST_NAME_MAX when <limits.h> does not define it.])
  95   fi
  96 ])
  97
  98 # Prerequisites of lib/gethostname.c.
  99 AC_DEFUN([gl_PREREQ_GETHOSTNAME], [
 100   if test "$gl_cv_w32_gethostname" != "yes"; then
 101     AC_CHECK_FUNCS([uname])
 102   fi
 103 ])