m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 25
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([isoc99_inline],
  16 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  17    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  18    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  19    __APPLE__ && __MACH__ test for MacOS X.
  20    __APPLE_CC__ tests for the Apple compiler and its version.
  21    __STDC_VERSION__ tests for the C99 mode.  */
  22 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  23 # define __GNUC_STDC_INLINE__ 1
  24 #endif])
  25   AH_VERBATIM([unused_parameter],
  26 [/* Define as a marker that can be attached to declarations that might not
  27     be used.  This helps to reduce warnings, such as from
  28     GCC -Wunused-parameter.  */
  29 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  30 # define _GL_UNUSED __attribute__ ((__unused__))
  31 #else
  32 # define _GL_UNUSED
  33 #endif
  34 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  35    is a misnomer outside of parameter lists.  */
  36 #define _UNUSED_PARAMETER_ _GL_UNUSED
  37
  38 /* The __pure__ attribute was added in gcc 2.96.  */
  39 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
  40 # define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
  41 #else
  42 # define _GL_ATTRIBUTE_PURE /* empty */
  43 #endif
  44
  45 /* The __const__ attribute was added in gcc 2.95.  */
  46 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
  47 # define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
  48 #else
  49 # define _GL_ATTRIBUTE_CONST /* empty */
  50 #endif
  51 ])
  52   dnl Preparation for running test programs:
  53   dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
  54   dnl to /dev/tty, so they can be redirected to log files.  Such diagnostics
  55   dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
  56   LIBC_FATAL_STDERR_=1
  57   export LIBC_FATAL_STDERR_
  58 ])
  59
  60 # gl_MODULE_INDICATOR_CONDITION
  61 # expands to a C preprocessor expression that evaluates to 1 or 0, depending
  62 # whether a gnulib module that has been requested shall be considered present
  63 # or not.
  64 AC_DEFUN([gl_MODULE_INDICATOR_CONDITION], [1])
  65
  66 # gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
  67 # sets the shell variable that indicates the presence of the given module to
  68 # a C preprocessor expression that will evaluate to 1.
  69 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
  70 [
  71   GNULIB_[]m4_translit([[$1]],
  72     [abcdefghijklmnopqrstuvwxyz./-],
  73     [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=gl_MODULE_INDICATOR_CONDITION
  74 ])
  75
  76 # gl_MODULE_INDICATOR([modulename])
  77 # defines a C macro indicating the presence of the given module
  78 # in a location where it can be used.
  79 #                                             |  Value  |   Value   |
  80 #                                             | in lib/ | in tests/ |
  81 # --------------------------------------------+---------+-----------+
  82 # Module present among main modules:          |    1    |     1     |
  83 # --------------------------------------------+---------+-----------+
  84 # Module present among tests-related modules: |    0    |     1     |
  85 # --------------------------------------------+---------+-----------+
  86 # Module not present at all:                  |    0    |     0     |
  87 # --------------------------------------------+---------+-----------+
  88 AC_DEFUN([gl_MODULE_INDICATOR],
  89 [
  90   AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
  91       [abcdefghijklmnopqrstuvwxyz./-],
  92       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
  93     [gl_MODULE_INDICATOR_CONDITION],
  94     [Define to a C preprocessor expression that evaluates to 1 or 0,
  95      depending whether the gnulib module $1 shall be considered present.])
  96 ])
  97
  98 # gl_MODULE_INDICATOR_FOR_TESTS([modulename])
  99 # defines a C macro indicating the presence of the given module
 100 # in lib or tests. This is useful to determine whether the module
 101 # should be tested.
 102 #                                             |  Value  |   Value   |
 103 #                                             | in lib/ | in tests/ |
 104 # --------------------------------------------+---------+-----------+
 105 # Module present among main modules:          |    1    |     1     |
 106 # --------------------------------------------+---------+-----------+
 107 # Module present among tests-related modules: |    1    |     1     |
 108 # --------------------------------------------+---------+-----------+
 109 # Module not present at all:                  |    0    |     0     |
 110 # --------------------------------------------+---------+-----------+
 111 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
 112 [
 113   AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
 114       [abcdefghijklmnopqrstuvwxyz./-],
 115       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
 116     [Define to 1 when the gnulib module $1 should be tested.])
 117 ])
 118
 119 # gl_ASSERT_NO_GNULIB_POSIXCHECK
 120 # asserts that there will never be a need to #define GNULIB_POSIXCHECK.
 121 # and thereby enables an optimization of configure and config.h.
 122 # Used by Emacs.
 123 AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
 124 [
 125   dnl Override gl_WARN_ON_USE_PREPARE.
 126   dnl But hide this definition from 'aclocal'.
 127   AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
 128 ])
 129
 130 # gl_ASSERT_NO_GNULIB_TESTS
 131 # asserts that there will be no gnulib tests in the scope of the configure.ac
 132 # and thereby enables an optimization of config.h.
 133 # Used by Emacs.
 134 AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
 135 [
 136   dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
 137   AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
 138 ])
 139
 140 # Test whether <features.h> exists.
 141 # Set HAVE_FEATURES_H.
 142 AC_DEFUN([gl_FEATURES_H],
 143 [
 144   AC_CHECK_HEADERS_ONCE([features.h])
 145   if test $ac_cv_header_features_h = yes; then
 146     HAVE_FEATURES_H=1
 147   else
 148     HAVE_FEATURES_H=0
 149   fi
 150   AC_SUBST([HAVE_FEATURES_H])
 151 ])
 152
 153 # m4_foreach_w
 154 # is a backport of autoconf-2.59c's m4_foreach_w.
 155 # Remove this macro when we can assume autoconf >= 2.60.
 156 m4_ifndef([m4_foreach_w],
 157   [m4_define([m4_foreach_w],
 158     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
 159
 160 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
 161 # ----------------------------------------------------
 162 # Backport of autoconf-2.63b's macro.
 163 # Remove this macro when we can assume autoconf >= 2.64.
 164 m4_ifndef([AS_VAR_IF],
 165 [m4_define([AS_VAR_IF],
 166 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 167
 168 # AC_PROG_MKDIR_P
 169 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
 170 # for interoperability with automake-1.9.6 from autoconf-2.62.
 171 # Remove this macro when we can assume autoconf >= 2.62 or
 172 # autoconf >= 2.60 && automake >= 1.10.
 173 m4_ifdef([AC_PROG_MKDIR_P], [
 174   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
 175   m4_define([AC_PROG_MKDIR_P],
 176     m4_defn([AC_PROG_MKDIR_P])[
 177     AC_SUBST([MKDIR_P])])], [
 178   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
 179   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
 180     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 181      MKDIR_P='$(mkdir_p)'
 182      AC_SUBST([MKDIR_P])])])
 183
 184 # AC_C_RESTRICT
 185 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
 186 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
 187 # works.
 188 # This definition can be removed once autoconf >= 2.62 can be assumed.
 189 m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.62]),[-1],[
 190 AC_DEFUN([AC_C_RESTRICT],
 191 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
 192   [ac_cv_c_restrict=no
 193    # The order here caters to the fact that C++ does not require restrict.
 194    for ac_kw in __restrict __restrict__ _Restrict restrict; do
 195      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 196       [[typedef int * int_ptr;
 197         int foo (int_ptr $ac_kw ip) {
 198         return ip[0];
 199        }]],
 200       [[int s[1];
 201         int * $ac_kw t = s;
 202         t[0] = 0;
 203         return foo(t)]])],
 204       [ac_cv_c_restrict=$ac_kw])
 205      test "$ac_cv_c_restrict" != no && break
 206    done
 207   ])
 208  AH_VERBATIM([restrict],
 209 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 210    nothing if this is not supported.  Do not define if restrict is
 211    supported directly.  */
 212 #undef restrict
 213 /* Work around a bug in Sun C++: it does not support _Restrict, even
 214    though the corresponding Sun C compiler does, which causes
 215    "#define restrict _Restrict" in the previous line.  Perhaps some future
 216    version of Sun C++ will work with _Restrict; if so, it'll probably
 217    define __RESTRICT, just as Sun C does.  */
 218 #if defined __SUNPRO_CC && !defined __RESTRICT
 219 # define _Restrict
 220 #endif])
 221  case $ac_cv_c_restrict in
 222    restrict) ;;
 223    no) AC_DEFINE([restrict], []) ;;
 224    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 225  esac
 226 ])
 227 ])
 228
 229 # gl_BIGENDIAN
 230 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 231 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 232 # macros invoke AC_C_BIGENDIAN with arguments.
 233 AC_DEFUN([gl_BIGENDIAN],
 234 [
 235   AC_C_BIGENDIAN
 236 ])
 237
 238 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 239 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 240 # output a spurious "(cached)" mark in the midst of other configure output.
 241 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 242 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 243 AC_DEFUN([gl_CACHE_VAL_SILENT],
 244 [
 245   saved_as_echo_n="$as_echo_n"
 246   as_echo_n=':'
 247   AC_CACHE_VAL([$1], [$2])
 248   as_echo_n="$saved_as_echo_n"
 249 ])