m4/host-os.m4

   1 #serial 3
   2
   3 dnl From Paul Eggert.
   4
   5 # Define HOST_OPERATING_SYSTEM to a name for the host operating system.
   6 AC_DEFUN([UTILS_HOST_OS],
   7 [
   8   AC_CACHE_CHECK([host operating system],
   9     utils_cv_host_operating_system,
  10
  11     [[case $host_os in
  12
  13        # These operating system names do not use the default heuristic below.
  14        # They are in reverse order, so that more-specific prefixes come first.
  15        winnt*)          os='Windows NT';;
  16        vos*)            os='VOS';;
  17        sysv*)           os='Unix System V';;
  18        superux*)        os='SUPER-UX';;
  19        sunos*)          os='SunOS';;
  20        stop*)           os='STOP';;
  21        sco*)            os='SCO Unix';;
  22        riscos*)         os='RISC OS';;
  23        riscix*)         os='RISCiX';;
  24        qnx*)            os='QNX';;
  25        pw32*)           os='PW32';;
  26        ptx*)            os='ptx';;
  27        plan9*)          os='Plan 9';;
  28        osf*)            os='Tru64';;
  29        os2*)            os='OS/2';;
  30        openbsd*)        os='OpenBSD';;
  31        nsk*)            os='NonStop Kernel';;
  32        nonstopux*)      os='NonStop-UX';;
  33        netbsd*)         os='NetBSD';;
  34        knetbsd*-gnu*)   os='GNU/KNetBSD';;
  35        kfreebsd*-gnu*)  os='GNU/KFreeBSD';;
  36        msdosdjgpp*)     os='DJGPP';;
  37        mpeix*)          os='MPE/iX';;
  38        mint*)           os='MiNT';;
  39        mingw*)          os='MinGW';;
  40        lynxos*)         os='LynxOS';;
  41        linux*)          os='GNU/Linux';;
  42        hpux*)           os='HP-UX';;
  43        hiux*)           os='HI-UX';;
  44        gnu*)            os='GNU';;
  45        freebsd*)        os='FreeBSD';;
  46        dgux*)           os='DG/UX';;
  47        bsdi*)           os='BSD/OS';;
  48        bsd*)            os='BSD';;
  49        beos*)           os='BeOS';;
  50        aux*)            os='A/UX';;
  51        atheos*)         os='AtheOS';;
  52        amigaos*)        os='Amiga OS';;
  53        aix*)            os='AIX';;
  54
  55        # The default heuristic takes the initial alphabetic string
  56        # from $host_os, but capitalizes its first letter.
  57        [A-Za-z]*)
  58          os=`
  59            expr "X$host_os" : 'X\([A-Za-z]\)' | tr '[a-z]' '[A-Z]'
  60          ``
  61            expr "X$host_os" : 'X.\([A-Za-z]*\)'
  62          `
  63          ;;
  64
  65        # If $host_os does not start with an alphabetic string, use it unchanged.
  66        *)
  67          os=$host_os;;
  68      esac
  69      utils_cv_host_operating_system=$os]])
  70   AC_DEFINE_UNQUOTED(HOST_OPERATING_SYSTEM,
  71     "$utils_cv_host_operating_system",
  72     [The host operating system.])
  73 ])