m4/inet_ntop.m4

   1 # inet_ntop.m4 serial 14
   2 dnl Copyright (C) 2005-2006, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_INET_NTOP],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_ntop.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   dnl Most platforms that provide inet_ntop define it in libc.
  13   dnl Solaris 8..10 provide inet_ntop in libnsl instead.
  14   gl_save_LIBS=$LIBS
  15   AC_SEARCH_LIBS([inet_ntop], [nsl], [],
  16     [AC_REPLACE_FUNCS([inet_ntop])])
  17   LIBS=$gl_save_LIBS
  18   INET_NTOP_LIB=
  19   if test "$ac_cv_search_inet_ntop" != "no" &&
  20      test "$ac_cv_search_inet_ntop" != "none required"; then
  21     INET_NTOP_LIB="$ac_cv_search_inet_ntop"
  22   fi
  23   AC_SUBST([INET_NTOP_LIB])
  24
  25   gl_PREREQ_INET_NTOP
  26 ])
  27
  28 # Prerequisites of lib/inet_ntop.c.
  29 AC_DEFUN([gl_PREREQ_INET_NTOP], [
  30   AC_CHECK_HEADERS_ONCE([netdb.h])
  31   AC_CHECK_DECLS([inet_ntop],,,
  32     [#include <arpa/inet.h>
  33      #if HAVE_NETDB_H
  34      # include <netdb.h>
  35      #endif
  36     ])
  37   if test $ac_cv_have_decl_inet_ntop = no; then
  38     HAVE_DECL_INET_NTOP=0
  39   fi
  40   AC_REQUIRE([gl_SOCKET_FAMILIES])
  41   AC_REQUIRE([AC_C_RESTRICT])
  42 ])