m4/inet_ntop.m4

   1 # inet_ntop.m4 serial 18
   2 dnl Copyright (C) 2005-2006, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_INET_NTOP],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_ntop.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   AC_REQUIRE([AC_C_RESTRICT])
  13
  14   dnl Most platforms that provide inet_ntop define it in libc.
  15   dnl Solaris 8..10 provide inet_ntop in libnsl instead.
  16   dnl Solaris 2.6..7 provide inet_ntop in libresolv instead.
  17   dnl Native Windows provides it in -lws2_32 instead, with a declaration in
  18   dnl <ws2tcpip.h>, and it uses stdcall calling convention, not cdecl
  19   dnl (hence we cannot use AC_CHECK_FUNCS, AC_SEARCH_LIBS to find it).
  20   HAVE_INET_NTOP=1
  21   INET_NTOP_LIB=
  22   gl_PREREQ_SYS_H_WINSOCK2
  23   if test $HAVE_WINSOCK2_H = 1; then
  24     AC_CHECK_DECLS([inet_ntop],,, [[#include <ws2tcpip.h>]])
  25     if test $ac_cv_have_decl_inet_ntop = yes; then
  26       dnl It needs to be overridden, because the stdcall calling convention
  27       dnl is not compliant with POSIX.
  28       REPLACE_INET_NTOP=1
  29       INET_NTOP_LIB="-lws2_32"
  30     else
  31       HAVE_DECL_INET_NTOP=0
  32       HAVE_INET_NTOP=0
  33     fi
  34   else
  35     gl_save_LIBS=$LIBS
  36     AC_SEARCH_LIBS([inet_ntop], [nsl resolv], [],
  37       [AC_CHECK_FUNCS([inet_ntop])
  38        if test $ac_cv_func_inet_ntop = no; then
  39          HAVE_INET_NTOP=0
  40        fi
  41       ])
  42     LIBS=$gl_save_LIBS
  43
  44     if test "$ac_cv_search_inet_ntop" != "no" \
  45        && test "$ac_cv_search_inet_ntop" != "none required"; then
  46       INET_NTOP_LIB="$ac_cv_search_inet_ntop"
  47     fi
  48
  49     AC_CHECK_HEADERS_ONCE([netdb.h])
  50     AC_CHECK_DECLS([inet_ntop],,,
  51       [[#include <arpa/inet.h>
  52         #if HAVE_NETDB_H
  53         # include <netdb.h>
  54         #endif
  55       ]])
  56     if test $ac_cv_have_decl_inet_ntop = no; then
  57       HAVE_DECL_INET_NTOP=0
  58     fi
  59   fi
  60   AC_SUBST([INET_NTOP_LIB])
  61 ])
  62
  63 # Prerequisites of lib/inet_ntop.c.
  64 AC_DEFUN([gl_PREREQ_INET_NTOP], [
  65   AC_REQUIRE([gl_SOCKET_FAMILIES])
  66 ])