m4/inet_ntop.m4

   1 # inet_ntop.m4 serial 13
   2 dnl Copyright (C) 2005-2006, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_INET_NTOP],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_ntop.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   gl_REPLACE_ARPA_INET_H
  13
  14   dnl Most platforms that provide inet_ntop define it in libc.
  15   dnl Solaris 8..10 provide inet_ntop in libnsl instead.
  16   gl_save_LIBS=$LIBS
  17   AC_SEARCH_LIBS([inet_ntop], [nsl], [],
  18     [AC_REPLACE_FUNCS([inet_ntop])])
  19   LIBS=$gl_save_LIBS
  20   INET_NTOP_LIB=
  21   if test "$ac_cv_search_inet_ntop" != "no" &&
  22      test "$ac_cv_search_inet_ntop" != "none required"; then
  23     INET_NTOP_LIB="$ac_cv_search_inet_ntop"
  24   fi
  25   AC_SUBST([INET_NTOP_LIB])
  26
  27   gl_PREREQ_INET_NTOP
  28 ])
  29
  30 # Prerequisites of lib/inet_ntop.c.
  31 AC_DEFUN([gl_PREREQ_INET_NTOP], [
  32   AC_CHECK_HEADERS_ONCE([netdb.h])
  33   AC_CHECK_DECLS([inet_ntop],,,
  34     [#include <arpa/inet.h>
  35      #if HAVE_NETDB_H
  36      # include <netdb.h>
  37      #endif
  38     ])
  39   if test $ac_cv_have_decl_inet_ntop = no; then
  40     HAVE_DECL_INET_NTOP=0
  41   fi
  42   AC_REQUIRE([gl_SOCKET_FAMILIES])
  43   AC_REQUIRE([AC_C_RESTRICT])
  44 ])