m4/inet_pton.m4

   1 # inet_pton.m4 serial 12
   2 dnl Copyright (C) 2006, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_INET_PTON],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_pton.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   dnl Most platforms that provide inet_pton define it in libc.
  13   dnl Solaris 8..10 provide inet_pton in libnsl instead.
  14   gl_save_LIBS=$LIBS
  15   AC_SEARCH_LIBS([inet_pton], [nsl], [],
  16     [AC_REPLACE_FUNCS([inet_pton])])
  17   LIBS=$gl_save_LIBS
  18   INET_PTON_LIB=
  19   if test "$ac_cv_search_inet_pton" != "no" &&
  20      test "$ac_cv_search_inet_pton" != "none required"; then
  21     INET_PTON_LIB="$ac_cv_search_inet_pton"
  22   fi
  23   AC_SUBST([INET_PTON_LIB])
  24
  25   gl_PREREQ_INET_PTON
  26 ])
  27
  28 # Prerequisites of lib/inet_pton.c.
  29 AC_DEFUN([gl_PREREQ_INET_PTON], [
  30   AC_CHECK_HEADERS_ONCE([netdb.h])
  31   AC_CHECK_DECLS([inet_pton],,,
  32     [#include <arpa/inet.h>
  33      #if HAVE_NETDB_H
  34      # include <netdb.h>
  35      #endif
  36     ])
  37   if test $ac_cv_have_decl_inet_pton = no; then
  38     HAVE_DECL_INET_PTON=0
  39   fi
  40   AC_REQUIRE([gl_SOCKET_FAMILIES])
  41   AC_REQUIRE([AC_C_RESTRICT])
  42 ])