m4/inttypes.m4

   1 # inttypes.m4 serial 6
   2 dnl Copyright (C) 2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Derek Price, Bruno Haible.
   8 dnl Test whether <inttypes.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_INTTYPES_H],
  11 [
  12   AC_REQUIRE([gl_STDINT_H])
  13   AC_REQUIRE([gt_INTTYPES_PRI])
  14   AC_CHECK_DECLS_ONCE([imaxabs])
  15   AC_CHECK_DECLS_ONCE([imaxdiv])
  16   AC_CHECK_DECLS_ONCE([strtoimax])
  17   AC_CHECK_DECLS_ONCE([strtoumax])
  18
  19   dnl Now see if we need a substitute <inttypes.h>.
  20   dnl A complete <inttypes.h> requires
  21   dnl   - a complete <stdint.h>,
  22   dnl   - the existence of an <inttypes.h>,
  23   dnl   - that imaxabs, imaxdiv, strtoimax, strtoumax are declared,
  24   dnl   - some additional tests.
  25   AC_CACHE_CHECK([whether inttypes.h conforms to C99],
  26                  [gl_cv_header_working_inttypes_h],
  27   [
  28     gl_cv_header_working_inttypes_h=no
  29     if test "$gl_cv_header_working_stdint_h" = yes \
  30        && test $ac_cv_header_inttypes_h = yes \
  31        && test "$ac_cv_have_decl_imaxabs" = yes \
  32        && test "$ac_cv_have_decl_imaxdiv" = yes \
  33        && test "$ac_cv_have_decl_strtoimax" = yes \
  34        && test "$ac_cv_have_decl_strtoumax" = yes; then
  35       AC_COMPILE_IFELSE([
  36         AC_LANG_PROGRAM([
  37 #include <stddef.h>
  38 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  39 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  40 #define __STDC_FORMAT_MACROS 1 /* to make it work also in C++ mode */
  41 #include ABSOLUTE_INTTYPES_H
  42
  43 /* No need to duplicate the tests of stdint.m4; they are subsumed by
  44    $gl_cv_header_working_stdint_h = yes.  */
  45
  46 /* Tests for macros supposed to be defined in inttypes.h.  */
  47
  48 const char *k = /* implicit string concatenation */
  49 #ifdef INT8_MAX
  50   PRId8 PRIi8
  51 #endif
  52 #ifdef UINT8_MAX
  53   PRIo8 PRIu8 PRIx8 PRIX8
  54 #endif
  55 #ifdef INT16_MAX
  56   PRId16 PRIi16
  57 #endif
  58 #ifdef UINT16_MAX
  59   PRIo16 PRIu16 PRIx16 PRIX16
  60 #endif
  61 #ifdef INT32_MAX
  62   PRId32 PRIi32
  63 #endif
  64 #ifdef UINT32_MAX
  65   PRIo32 PRIu32 PRIx32 PRIX32
  66 #endif
  67 #ifdef INT64_MAX
  68   PRId64 PRIi64
  69 #endif
  70 #ifdef UINT64_MAX
  71   PRIo64 PRIu64 PRIx64 PRIX64
  72 #endif
  73   PRIdLEAST8 PRIiLEAST8 PRIoLEAST8 PRIuLEAST8 PRIxLEAST8 PRIXLEAST8
  74   PRIdLEAST16 PRIiLEAST16 PRIoLEAST16 PRIuLEAST16 PRIxLEAST16 PRIXLEAST16
  75   PRIdLEAST32 PRIiLEAST32 PRIoLEAST32 PRIuLEAST32 PRIxLEAST32 PRIXLEAST32
  76   PRIdLEAST64 PRIiLEAST64
  77   PRIoLEAST64 PRIuLEAST64 PRIxLEAST64 PRIXLEAST64
  78   PRIdFAST8 PRIiFAST8 PRIoFAST8 PRIuFAST8 PRIxFAST8 PRIXFAST8
  79   PRIdFAST16 PRIiFAST16 PRIoFAST16 PRIuFAST16 PRIxFAST16 PRIXFAST16
  80   PRIdFAST32 PRIiFAST32 PRIoFAST32 PRIuFAST32 PRIxFAST32 PRIXFAST32
  81   PRIdFAST64 PRIiFAST64
  82   PRIoFAST64 PRIuFAST64 PRIxFAST64 PRIXFAST64
  83   PRIdMAX PRIiMAX PRIoMAX PRIuMAX PRIxMAX PRIXMAX
  84 #ifdef INTPTR_MAX
  85   PRIdPTR PRIiPTR
  86 #endif
  87 #ifdef UINTPTR_MAX
  88   PRIoPTR PRIuPTR PRIxPTR PRIXPTR
  89 #endif
  90   ;
  91 const char *l = /* implicit string concatenation */
  92 #ifdef INT8_MAX
  93   SCNd8 SCNi8
  94 #endif
  95 #ifdef UINT8_MAX
  96   SCNo8 SCNu8 SCNx8
  97 #endif
  98 #ifdef INT16_MAX
  99   SCNd16 SCNi16
 100 #endif
 101 #ifdef UINT16_MAX
 102   SCNo16 SCNu16 SCNx16
 103 #endif
 104 #ifdef INT32_MAX
 105   SCNd32 SCNi32
 106 #endif
 107 #ifdef UINT32_MAX
 108   SCNo32 SCNu32 SCNx32
 109 #endif
 110 #ifdef INT64_MAX
 111   SCNd64 SCNi64
 112 #endif
 113 #ifdef UINT64_MAX
 114   SCNo64 SCNu64 SCNx64
 115 #endif
 116   SCNdLEAST8 SCNiLEAST8 SCNoLEAST8 SCNuLEAST8 SCNxLEAST8
 117   SCNdLEAST16 SCNiLEAST16 SCNoLEAST16 SCNuLEAST16 SCNxLEAST16
 118   SCNdLEAST32 SCNiLEAST32 SCNoLEAST32 SCNuLEAST32 SCNxLEAST32
 119   SCNdLEAST64 SCNiLEAST64
 120   SCNoLEAST64 SCNuLEAST64 SCNxLEAST64
 121   SCNdFAST8 SCNiFAST8 SCNoFAST8 SCNuFAST8 SCNxFAST8
 122   SCNdFAST16 SCNiFAST16 SCNoFAST16 SCNuFAST16 SCNxFAST16
 123   SCNdFAST32 SCNiFAST32 SCNoFAST32 SCNuFAST32 SCNxFAST32
 124   SCNdFAST64 SCNiFAST64
 125   SCNoFAST64 SCNuFAST64 SCNxFAST64
 126   SCNdMAX SCNiMAX SCNoMAX SCNuMAX SCNxMAX
 127 #ifdef INTPTR_MAX
 128   SCNdPTR SCNiPTR
 129 #endif
 130 #ifdef UINTPTR_MAX
 131   SCNoPTR SCNuPTR SCNxPTR
 132 #endif
 133   ;
 134         ])],
 135         [gl_cv_header_working_inttypes_h=yes])
 136     fi])
 137   if test $gl_cv_header_working_inttypes_h = yes; then
 138     dnl Use the existing <inttypes.h>.
 139     INTTYPES_H=''
 140   else
 141
 142     dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
 143     if test $ac_cv_header_inttypes_h = yes; then
 144       gl_ABSOLUTE_HEADER([inttypes.h])
 145       ABSOLUTE_INTTYPES_H=\"$gl_cv_absolute_inttypes_h\"
 146     else
 147       ABSOLUTE_INTTYPES_H=\"no/such/file/inttypes.h\"
 148     fi
 149     AC_SUBST([ABSOLUTE_INTTYPES_H])
 150
 151     PRIPTR_PREFIX=
 152     if test -n "$STDINT_H"; then
 153       dnl Using the gnulib <stdint.h>. It always defines intptr_t to 'long'.
 154       PRIPTR_PREFIX='"l"'
 155     else
 156       dnl Using the system's <stdint.h>.
 157       for glpfx in '' l ll I64; do
 158         case $glpfx in
 159           '')  gltype1='int';;
 160           l)   gltype1='long int';;
 161           ll)  gltype1='long long int';;
 162           I64) gltype1='__int64';;
 163         esac
 164         AC_COMPILE_IFELSE(
 165           [AC_LANG_PROGRAM([#include <stdint.h>
 166              extern intptr_t foo;
 167              extern $gltype1 foo;])],
 168           [PRIPTR_PREFIX='"'$glpfx'"'])
 169         test -n "$PRIPTR_PREFIX" && break
 170       done
 171     fi
 172     AC_SUBST([PRIPTR_PREFIX])
 173
 174     if test "$ac_cv_have_decl_imaxabs" = yes; then
 175       HAVE_DECL_IMAXABS=1
 176     else
 177       HAVE_DECL_IMAXABS=0
 178     fi
 179     AC_SUBST([HAVE_DECL_IMAXABS])
 180
 181     if test "$ac_cv_have_decl_imaxdiv" = yes; then
 182       HAVE_DECL_IMAXDIV=1
 183     else
 184       HAVE_DECL_IMAXDIV=0
 185     fi
 186     AC_SUBST([HAVE_DECL_IMAXDIV])
 187
 188     if test "$ac_cv_have_decl_strtoimax" = yes; then
 189       HAVE_DECL_STRTOIMAX=1
 190     else
 191       HAVE_DECL_STRTOIMAX=0
 192     fi
 193     AC_SUBST([HAVE_DECL_STRTOIMAX])
 194
 195     if test "$ac_cv_have_decl_strtoumax" = yes; then
 196       HAVE_DECL_STRTOUMAX=1
 197     else
 198       HAVE_DECL_STRTOUMAX=0
 199     fi
 200     AC_SUBST([HAVE_DECL_STRTOUMAX])
 201
 202     INTTYPES_H='inttypes.h'
 203   fi
 204   AC_SUBST(INTTYPES_H)
 205 ])