m4/ioctl.m4

   1 # ioctl.m4 serial 2
   2 dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_IOCTL],
   8 [
   9   AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])
  10   AC_REQUIRE([gl_HEADER_SYS_SOCKET])
  11   if test "$ac_cv_header_winsock2_h" = yes; then
  12     dnl Even if the 'socket' module is not used here, another part of the
  13     dnl application may use it and pass file descriptors that refer to
  14     dnl sockets to the ioctl() function. So enable the support for sockets.
  15     AC_LIBOBJ([ioctl])
  16   else
  17     AC_CHECK_FUNCS([ioctl])
  18     dnl On glibc systems, the second parameter is 'unsigned long int request',
  19     dnl not 'int request'. We cannot simply cast the function pointer, but
  20     dnl instead need a wrapper.
  21     AC_CACHE_CHECK([for ioctl with POSIX signature],
  22       [gl_cv_func_ioctl_posix_signature],
  23       [AC_COMPILE_IFELSE(
  24          [AC_LANG_PROGRAM(
  25             [[#include <sys/ioctl.h>]],
  26             [[extern int ioctl (int, int, ...);]])
  27          ],
  28          [gl_cv_func_ioctl_posix_signature=yes],
  29          [gl_cv_func_ioctl_posix_signature=no])
  30       ])
  31     if test $gl_cv_func_ioctl_posix_signature != yes; then
  32       REPLACE_IOCTL=1
  33       AC_LIBOBJ([ioctl])
  34     fi
  35   fi
  36 ])