m4/isfinite.m4

   1 # isfinite.m4 serial 8
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_ISFINITE],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare isfinite.
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   AC_CHECK_DECLS([isfinite], , , [#include <math.h>])
  13   if test "$ac_cv_have_decl_isfinite" = yes; then
  14     gl_CHECK_MATH_LIB([ISFINITE_LIBM], [x = isfinite (x);])
  15     if test "$ISFINITE_LIBM" != missing; then
  16       dnl Test whether isfinite() on 'long double' works.
  17       gl_ISFINITEL_WORKS
  18       case "$gl_cv_func_isfinitel_works" in
  19         *yes) ;;
  20         *)    ISFINITE_LIBM=missing;;
  21       esac
  22       dnl Also, isfinite() on 'double' does not work on Linux/ia64 (because of
  23       dnl signalling NaNs). But this does not have to be tested, since
  24       dnl isfinite(long double) also does not work in this situation.
  25     fi
  26   fi
  27   if test "$ac_cv_have_decl_isfinite" != yes ||
  28      test "$ISFINITE_LIBM" = missing; then
  29     REPLACE_ISFINITE=1
  30     AC_LIBOBJ([isfinite])
  31     ISFINITE_LIBM=
  32   fi
  33   AC_SUBST([ISFINITE_LIBM])
  34 ])
  35
  36 dnl Test whether isfinite() on 'long double' recognizes all numbers which are
  37 dnl neither finite nor infinite. This test fails e.g. on i686, x86_64, ia64,
  38 dnl because of
  39 dnl - pseudo-denormals on x86_64,
  40 dnl - pseudo-zeroes, unnormalized numbers, and pseudo-denormals on i686,
  41 dnl - pseudo-NaN, pseudo-Infinity, pseudo-zeroes, unnormalized numbers, and
  42 dnl   pseudo-denormals on ia64.
  43 AC_DEFUN([gl_ISFINITEL_WORKS],
  44 [
  45   AC_REQUIRE([AC_PROG_CC])
  46   AC_REQUIRE([gl_BIGENDIAN])
  47   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  48   AC_CACHE_CHECK([whether isfinite(long double) works], [gl_cv_func_isfinitel_works],
  49     [
  50       AC_RUN_IFELSE([AC_LANG_SOURCE([[
  51 #include <float.h>
  52 #include <limits.h>
  53 #include <math.h>
  54 #define NWORDS \
  55   ((sizeof (long double) + sizeof (unsigned int) - 1) / sizeof (unsigned int))
  56 typedef union { unsigned int word[NWORDS]; long double value; }
  57         memory_long_double;
  58 /* On Irix 6.5, gcc 3.4.3 can't compute compile-time NaN, and needs the
  59    runtime type conversion.  */
  60 #ifdef __sgi
  61 static long double NaNl ()
  62 {
  63   double zero = 0.0;
  64   return zero / zero;
  65 }
  66 #else
  67 # define NaNl() (0.0L / 0.0L)
  68 #endif
  69 int main ()
  70 {
  71   int result = 0;
  72
  73   {
  74     memory_long_double m;
  75     unsigned int i;
  76
  77     /* The isfinite macro should be immune against changes in the sign bit and
  78        in the mantissa bits.  The xor operation twiddles a bit that can only be
  79        a sign bit or a mantissa bit (since the exponent never extends to
  80        bit 31).  */
  81     m.value = NaNl ();
  82     m.word[NWORDS / 2] ^= (unsigned int) 1 << (sizeof (unsigned int) * CHAR_BIT - 1);
  83     for (i = 0; i < NWORDS; i++)
  84       m.word[i] |= 1;
  85     if (isfinite (m.value))
  86       result |= 1;
  87   }
  88
  89 #if ((defined __ia64 && LDBL_MANT_DIG == 64) || (defined __x86_64__ || defined __amd64__) || (defined __i386 || defined __i386__ || defined _I386 || defined _M_IX86 || defined _X86_))
  90 /* Representation of an 80-bit 'long double' as an initializer for a sequence
  91    of 'unsigned int' words.  */
  92 # ifdef WORDS_BIGENDIAN
  93 #  define LDBL80_WORDS(exponent,manthi,mantlo) \
  94      { ((unsigned int) (exponent) << 16) | ((unsigned int) (manthi) >> 16), \
  95        ((unsigned int) (manthi) << 16) | (unsigned int) (mantlo) >> 16),    \
  96        (unsigned int) (mantlo) << 16                                        \
  97      }
  98 # else
  99 #  define LDBL80_WORDS(exponent,manthi,mantlo) \
 100      { mantlo, manthi, exponent }
 101 # endif
 102   { /* Quiet NaN.  */
 103     static memory_long_double x =
 104       { LDBL80_WORDS (0xFFFF, 0xC3333333, 0x00000000) };
 105     if (isfinite (x.value))
 106       result |= 2;
 107   }
 108   {
 109     /* Signalling NaN.  */
 110     static memory_long_double x =
 111       { LDBL80_WORDS (0xFFFF, 0x83333333, 0x00000000) };
 112     if (isfinite (x.value))
 113       result |= 2;
 114   }
 115   /* The isfinite macro should recognize Pseudo-NaNs, Pseudo-Infinities,
 116      Pseudo-Zeroes, Unnormalized Numbers, and Pseudo-Denormals, as defined in
 117        Intel IA-64 Architecture Software Developer's Manual, Volume 1:
 118        Application Architecture.
 119        Table 5-2 "Floating-Point Register Encodings"
 120        Figure 5-6 "Memory to Floating-Point Register Data Translation"
 121    */
 122   { /* Pseudo-NaN.  */
 123     static memory_long_double x =
 124       { LDBL80_WORDS (0xFFFF, 0x40000001, 0x00000000) };
 125     if (isfinite (x.value))
 126       result |= 4;
 127   }
 128   { /* Pseudo-Infinity.  */
 129     static memory_long_double x =
 130       { LDBL80_WORDS (0xFFFF, 0x00000000, 0x00000000) };
 131     if (isfinite (x.value))
 132       result |= 8;
 133   }
 134   { /* Pseudo-Zero.  */
 135     static memory_long_double x =
 136       { LDBL80_WORDS (0x4004, 0x00000000, 0x00000000) };
 137     if (isfinite (x.value))
 138       result |= 16;
 139   }
 140   { /* Unnormalized number.  */
 141     static memory_long_double x =
 142       { LDBL80_WORDS (0x4000, 0x63333333, 0x00000000) };
 143     if (isfinite (x.value))
 144       result |= 32;
 145   }
 146   { /* Pseudo-Denormal.  */
 147     static memory_long_double x =
 148       { LDBL80_WORDS (0x0000, 0x83333333, 0x00000000) };
 149     if (isfinite (x.value))
 150       return |= 64;
 151   }
 152 #endif
 153
 154   return result;
 155 }]])], [gl_cv_func_isfinitel_works=yes], [gl_cv_func_isfinitel_works=no],
 156       [case "$host_cpu" in
 157                                # Guess no on ia64, x86_64, i386.
 158          ia64 | x86_64 | i*86) gl_cv_func_isnanl_works="guessing no";;
 159          *)                    gl_cv_func_isnanl_works="guessing yes";;
 160        esac
 161       ])
 162     ])
 163 ])