m4/isinf.m4

   1 # isinf.m4 serial 7
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_ISINF],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare isinf.
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12   AC_CHECK_DECLS([isinf], , , [[#include <math.h>]])
  13   if test "$ac_cv_have_decl_isinf" = yes; then
  14     gl_CHECK_MATH_LIB([ISINF_LIBM], [x = isinf (x) + isinf ((float) x);])
  15     if test "$ISINF_LIBM" != missing; then
  16       dnl Test whether isinf() on 'long double' works.
  17       gl_ISINFL_WORKS
  18       case "$gl_cv_func_isinfl_works" in
  19         *yes) ;;
  20         *)    ISINF_LIBM=missing;;
  21       esac
  22     fi
  23   fi
  24   if test "$ac_cv_have_decl_isinf" != yes ||
  25      test "$ISINF_LIBM" = missing; then
  26     REPLACE_ISINF=1
  27     dnl No libraries are needed to link lib/isinf.c.
  28     ISINF_LIBM=
  29   fi
  30   AC_SUBST([ISINF_LIBM])
  31 ])
  32
  33 dnl Test whether isinf() works:
  34 dnl 1) Whether it correctly returns false for LDBL_MAX.
  35 dnl 2) Whether on 'long double' recognizes all numbers which are neither
  36 dnl    finite nor infinite. This test fails on OpenBSD/x86, but could also
  37 dnl    fail e.g. on i686, x86_64, ia64, because of
  38 dnl    - pseudo-denormals on x86_64,
  39 dnl    - pseudo-zeroes, unnormalized numbers, and pseudo-denormals on i686,
  40 dnl    - pseudo-NaN, pseudo-Infinity, pseudo-zeroes, unnormalized numbers, and
  41 dnl      pseudo-denormals on ia64.
  42 AC_DEFUN([gl_ISINFL_WORKS],
  43 [
  44   AC_REQUIRE([AC_PROG_CC])
  45   AC_REQUIRE([gl_BIGENDIAN])
  46   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  47   AC_CACHE_CHECK([whether isinf(long double) works], [gl_cv_func_isinfl_works],
  48     [
  49       AC_RUN_IFELSE(
  50         [AC_LANG_SOURCE([[
  51 #include <float.h>
  52 #include <limits.h>
  53 #include <math.h>
  54 #define NWORDS \
  55   ((sizeof (long double) + sizeof (unsigned int) - 1) / sizeof (unsigned int))
  56 typedef union { unsigned int word[NWORDS]; long double value; }
  57         memory_long_double;
  58 /* On Irix 6.5, gcc 3.4.3 can't compute compile-time NaN, and needs the
  59    runtime type conversion.  */
  60 #ifdef __sgi
  61 static long double NaNl ()
  62 {
  63   double zero = 0.0;
  64   return zero / zero;
  65 }
  66 #else
  67 # define NaNl() (0.0L / 0.0L)
  68 #endif
  69 int main ()
  70 {
  71   int result = 0;
  72
  73   if (isinf (LDBL_MAX))
  74     result |= 1;
  75
  76   {
  77     memory_long_double m;
  78     unsigned int i;
  79
  80     /* The isinf macro should be immune against changes in the sign bit and
  81        in the mantissa bits.  The xor operation twiddles a bit that can only be
  82        a sign bit or a mantissa bit (since the exponent never extends to
  83        bit 31).  */
  84     m.value = NaNl ();
  85     m.word[NWORDS / 2] ^= (unsigned int) 1 << (sizeof (unsigned int) * CHAR_BIT - 1);
  86     for (i = 0; i < NWORDS; i++)
  87       m.word[i] |= 1;
  88     if (isinf (m.value))
  89       result |= 2;
  90   }
  91
  92 #if ((defined __ia64 && LDBL_MANT_DIG == 64) || (defined __x86_64__ || defined __amd64__) || (defined __i386 || defined __i386__ || defined _I386 || defined _M_IX86 || defined _X86_))
  93 /* Representation of an 80-bit 'long double' as an initializer for a sequence
  94    of 'unsigned int' words.  */
  95 # ifdef WORDS_BIGENDIAN
  96 #  define LDBL80_WORDS(exponent,manthi,mantlo) \
  97      { ((unsigned int) (exponent) << 16) | ((unsigned int) (manthi) >> 16), \
  98        ((unsigned int) (manthi) << 16) | (unsigned int) (mantlo) >> 16),    \
  99        (unsigned int) (mantlo) << 16                                        \
 100      }
 101 # else
 102 #  define LDBL80_WORDS(exponent,manthi,mantlo) \
 103      { mantlo, manthi, exponent }
 104 # endif
 105   { /* Quiet NaN.  */
 106     static memory_long_double x =
 107       { LDBL80_WORDS (0xFFFF, 0xC3333333, 0x00000000) };
 108     if (isinf (x.value))
 109       result |= 2;
 110   }
 111   {
 112     /* Signalling NaN.  */
 113     static memory_long_double x =
 114       { LDBL80_WORDS (0xFFFF, 0x83333333, 0x00000000) };
 115     if (isinf (x.value))
 116       result |= 2;
 117   }
 118   /* The isinf macro should recognize Pseudo-NaNs, Pseudo-Infinities,
 119      Pseudo-Zeroes, Unnormalized Numbers, and Pseudo-Denormals, as defined in
 120        Intel IA-64 Architecture Software Developer's Manual, Volume 1:
 121        Application Architecture.
 122        Table 5-2 "Floating-Point Register Encodings"
 123        Figure 5-6 "Memory to Floating-Point Register Data Translation"
 124    */
 125   { /* Pseudo-NaN.  */
 126     static memory_long_double x =
 127       { LDBL80_WORDS (0xFFFF, 0x40000001, 0x00000000) };
 128     if (isinf (x.value))
 129       result |= 4;
 130   }
 131   { /* Pseudo-Infinity.  */
 132     static memory_long_double x =
 133       { LDBL80_WORDS (0xFFFF, 0x00000000, 0x00000000) };
 134     if (isinf (x.value))
 135       result |= 8;
 136   }
 137   { /* Pseudo-Zero.  */
 138     static memory_long_double x =
 139       { LDBL80_WORDS (0x4004, 0x00000000, 0x00000000) };
 140     if (isinf (x.value))
 141       result |= 16;
 142   }
 143   { /* Unnormalized number.  */
 144     static memory_long_double x =
 145       { LDBL80_WORDS (0x4000, 0x63333333, 0x00000000) };
 146     if (isinf (x.value))
 147       result |= 32;
 148   }
 149   { /* Pseudo-Denormal.  */
 150     static memory_long_double x =
 151       { LDBL80_WORDS (0x0000, 0x83333333, 0x00000000) };
 152     if (isinf (x.value))
 153       result |= 64;
 154   }
 155 #endif
 156
 157   return result;
 158 }]])], [gl_cv_func_isinfl_works=yes], [gl_cv_func_isinfl_works=no],
 159       [
 160        case "$host" in
 161            # Guess no on OpenBSD ia64, x86_64, i386.
 162          ia64-*-openbsd* | x86_64-*-openbsd* | i*86-*-openbsd*)
 163             gl_cv_func_isinfl_works="guessing no";;
 164          *)
 165             gl_cv_func_isinfl_works="guessing yes";;
 166        esac
 167       ])
 168     ])
 169 ])