m4/jm-macros.m4

   1 #serial 12
   2
   3 dnl Misc type-related macros for fileutils, sh-utils, textutils.
   4
   5 AC_DEFUN(jm_MACROS,
   6 [
   7   AC_PREREQ(2.14a)
   8
   9   GNU_PACKAGE="GNU $PACKAGE"
  10   AC_DEFINE_UNQUOTED(GNU_PACKAGE, "$GNU_PACKAGE",
  11     [The concatenation of the strings `GNU ', and PACKAGE.])
  12   AC_SUBST(GNU_PACKAGE)
  13
  14   dnl This macro actually runs replacement code.  See isc-posix.m4.
  15   AC_REQUIRE([AC_ISC_POSIX])dnl
  16
  17   jm_INCLUDED_REGEX([lib/regex.c])
  18
  19   AC_REQUIRE([jm_BISON])
  20   AC_REQUIRE([jm_ASSERT])
  21   AC_REQUIRE([jm_AC_HEADER_INTTYPES_H])
  22   AC_REQUIRE([jm_CHECK_TYPE_STRUCT_UTIMBUF])
  23   AC_REQUIRE([jm_CHECK_TYPE_STRUCT_DIRENT_D_TYPE])
  24   AC_REQUIRE([jm_CHECK_TYPE_STRUCT_DIRENT_D_INO])
  25   AC_REQUIRE([jm_CHECK_DECLS])
  26
  27   AC_REQUIRE([jm_PREREQ])
  28
  29   AC_REQUIRE([jm_FUNC_LCHOWN])
  30   AC_REQUIRE([jm_FUNC_CHOWN])
  31   AC_REQUIRE([jm_FUNC_MKTIME])
  32   AC_REQUIRE([jm_FUNC_LSTAT])
  33   AC_REQUIRE([jm_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK])
  34   AC_REQUIRE([jm_FUNC_STAT])
  35   AC_REQUIRE([jm_FUNC_REALLOC])
  36   AC_REQUIRE([jm_FUNC_MALLOC])
  37   AC_REQUIRE([jm_FUNC_STRERROR_R])
  38   AC_REQUIRE([jm_FUNC_NANOSLEEP])
  39   AC_REQUIRE([jm_FUNC_READDIR])
  40   AC_REQUIRE([jm_FUNC_MEMCMP])
  41   AC_REQUIRE([jm_FUNC_GLIBC_UNLOCKED_IO])
  42   AC_REQUIRE([jm_FUNC_FNMATCH])
  43   AC_REQUIRE([jm_AFS])
  44   AC_REQUIRE([jm_AC_PREREQ_XSTRTOUMAX])
  45   AC_REQUIRE([jm_AC_FUNC_LINK_FOLLOWS_SYMLINK])
  46
  47   AC_REPLACE_FUNCS(strcasecmp strncasecmp)
  48   AC_REPLACE_FUNCS(dup2)
  49
  50   dnl used by e.g. intl/*domain.c and lib/canon-host.c
  51   AC_REPLACE_FUNCS(strdup)
  52
  53   AC_REPLACE_FUNCS(memchr)
  54   AC_REPLACE_FUNCS(memmove)
  55   AC_CHECK_FUNCS(getpagesize)
  56
  57   # By default, argmatch should fail calling usage (1).
  58   AC_DEFINE(ARGMATCH_DIE, [usage (1)],
  59             [Define to the function xargmatch calls on failures.])
  60   AC_DEFINE(ARGMATCH_DIE_DECL, [extern void usage ()],
  61             [Define to the declaration of the xargmatch failure function.])
  62
  63   dnl Used to define SETVBUF in sys2.h.
  64   dnl This evokes the following warning from autoconf:
  65   dnl ...: warning: AC_TRY_RUN called without default to allow cross compiling
  66   AC_FUNC_SETVBUF_REVERSED
  67
  68   # used by sleep and shred
  69   # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
  70   # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
  71   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
  72   AC_CHECK_FUNCS(clock_gettime)
  73   AC_CHECK_FUNCS(gettimeofday)
  74
  75   AM_FUNC_GETLINE
  76   if test $am_cv_func_working_getline != yes; then
  77     AC_CHECK_FUNCS(getdelim)
  78   fi
  79
  80 ])
  81
  82 AC_DEFUN(jm_CHECK_ALL_TYPES,
  83 [
  84   dnl Checks for typedefs, structures, and compiler characteristics.
  85   AC_C_BIGENDIAN
  86   AC_C_CONST
  87   AC_C_INLINE
  88   AC_C_LONG_DOUBLE
  89
  90   AC_HEADER_DIRENT
  91   AC_HEADER_STDC
  92   AC_CHECK_MEMBERS((struct stat.st_blksize))
  93   AC_STRUCT_ST_BLOCKS
  94
  95   AC_STRUCT_TM
  96   AC_HEADER_TIME
  97   AC_STRUCT_TIMEZONE
  98   AC_HEADER_STAT
  99   AC_STRUCT_ST_MTIM_NSEC
 100   AC_STRUCT_ST_DM_MODE
 101   AC_REQUIRE([jm_CHECK_TYPE_STRUCT_TIMESPEC])
 102
 103   AC_TYPE_GETGROUPS
 104   AC_TYPE_MODE_T
 105   AC_TYPE_OFF_T
 106   AC_TYPE_PID_T
 107   AC_TYPE_SIGNAL
 108   AC_TYPE_SIZE_T
 109   AC_TYPE_UID_T
 110   AC_CHECK_TYPE(ino_t, unsigned long)
 111
 112   dnl This relies on the fact that autoconf 2.14a's implementation of
 113   dnl AC_CHECK_TYPE checks includes unistd.h.
 114   AC_CHECK_TYPE(ssize_t, int)
 115
 116   AC_REQUIRE([jm_AC_TYPE_UINTMAX_T])
 117   AC_REQUIRE([jm_AC_TYPE_UNSIGNED_LONG_LONG])
 118 ])