m4/largefile.m4

   1 #serial 6
   2
   3 dnl By default, many hosts won't let programs access large files;
   4 dnl one must use special compiler options to get large-file access to work.
   5 dnl For more details about this brain damage please see:
   6 dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
   7
   8 dnl Written by Paul Eggert <eggert@twinsun.com>.
   9
  10 dnl Internal subroutine of AC_SYS_LARGEFILE.
  11 dnl AC_SYS_LARGEFILE_FLAGS(FLAGSNAME)
  12 AC_DEFUN(AC_SYS_LARGEFILE_FLAGS,
  13   [AC_CACHE_CHECK([for $1 value to request large file support],
  14      ac_cv_sys_largefile_$1,
  15      [ac_cv_sys_largefile_$1=`($GETCONF LFS_$1) 2>/dev/null` || {
  16         ac_cv_sys_largefile_$1=no
  17         ifelse($1, CFLAGS,
  18           [case "$host_os" in
  19            # HP-UX 10.20 requires -D__STDC_EXT__ with gcc 2.95.1.
  20 changequote(, )dnl
  21            hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
  22 changequote([, ])dnl
  23              if test "$GCC" = yes; then
  24                ac_cv_sys_largefile_CFLAGS=-D__STDC_EXT__
  25              fi
  26              ;;
  27            # IRIX 6.2 and later require cc -n32.
  28 changequote(, )dnl
  29            irix6.[2-9]* | irix6.1[0-9]* | irix[7-9].* | irix[1-9][0-9]*)
  30 changequote([, ])dnl
  31              if test "$GCC" != yes; then
  32                ac_cv_sys_largefile_CFLAGS=-n32
  33              fi
  34            esac
  35            if test "$ac_cv_sys_largefile_CFLAGS" != no; then
  36              ac_save_CC="$CC"
  37              CC="$CC $ac_cv_sys_largefile_CFLAGS"
  38              AC_TRY_LINK(, , , ac_cv_sys_largefile_CFLAGS=no)
  39              CC="$ac_save_CC"
  40            fi])
  41       }])])
  42
  43 dnl Internal subroutine of AC_SYS_LARGEFILE.
  44 dnl AC_SYS_LARGEFILE_SPACE_APPEND(VAR, VAL)
  45 AC_DEFUN(AC_SYS_LARGEFILE_SPACE_APPEND,
  46   [case $2 in
  47    no) ;;
  48    ?*)
  49      case "[$]$1" in
  50      '') $1=$2 ;;
  51      *) $1=[$]$1' '$2 ;;
  52      esac ;;
  53    esac])
  54
  55 dnl Internal subroutine of AC_SYS_LARGEFILE.
  56 dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, CACHE-VAR, COMMENT, CODE-TO-SET-DEFAULT)
  57 AC_DEFUN(AC_SYS_LARGEFILE_MACRO_VALUE,
  58   [AC_CACHE_CHECK([for $1], $2,
  59      [$2=no
  60 changequote(, )dnl
  61       $4
  62       for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
  63         case "$ac_flag" in
  64         -D$1)
  65           $2=1 ;;
  66         -D$1=*)
  67           $2=`expr " $ac_flag" : '[^=]*=\(.*\)'` ;;
  68         esac
  69       done
  70 changequote([, ])dnl
  71       ])
  72    if test "[$]$2" != no; then
  73      AC_DEFINE_UNQUOTED([$1], [$]$2, [$3])
  74    fi])
  75
  76 AC_DEFUN(AC_SYS_LARGEFILE,
  77   [AC_REQUIRE([AC_CANONICAL_HOST])
  78    AC_ARG_ENABLE(largefile,
  79      [  --disable-largefile     omit support for large files])
  80    if test "$enable_largefile" != no; then
  81      AC_CHECK_TOOL(GETCONF, getconf)
  82      AC_SYS_LARGEFILE_FLAGS(CFLAGS)
  83      AC_SYS_LARGEFILE_FLAGS(LDFLAGS)
  84      AC_SYS_LARGEFILE_FLAGS(LIBS)
  85
  86      for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
  87        case "$ac_flag" in
  88        no) ;;
  89        -D_FILE_OFFSET_BITS=*) ;;
  90        -D_LARGEFILE_SOURCE | -D_LARGEFILE_SOURCE=*) ;;
  91        -D_LARGE_FILES | -D_LARGE_FILES=*) ;;
  92        -D?* | -I?*)
  93          AC_SYS_LARGEFILE_SPACE_APPEND(CPPFLAGS, "$ac_flag") ;;
  94        *)
  95          AC_SYS_LARGEFILE_SPACE_APPEND(CFLAGS, "$ac_flag") ;;
  96        esac
  97      done
  98      AC_SYS_LARGEFILE_SPACE_APPEND(LDFLAGS, "$ac_cv_sys_largefile_LDFLAGS")
  99      AC_SYS_LARGEFILE_SPACE_APPEND(LIBS, "$ac_cv_sys_largefile_LIBS")
 100      AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS,
 101        ac_cv_sys_file_offset_bits,
 102        [Number of bits in a file offset, on hosts where this is settable.],
 103        [case "$host_os" in
 104         # HP-UX 10.20 and later
 105         hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
 106           ac_cv_sys_file_offset_bits=64 ;;
 107         esac])
 108      AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE,
 109        ac_cv_sys_largefile_source,
 110        [Define to make fseeko etc. visible, on some hosts.],
 111        [case "$host_os" in
 112         # HP-UX 10.20 and later
 113         hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)
 114           ac_cv_sys_largefile_source=1 ;;
 115         esac])
 116      AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES,
 117        ac_cv_sys_large_files,
 118        [Define for large files, on AIX-style hosts.],
 119        [case "$host_os" in
 120         # AIX 4.2 and later
 121         aix4.[2-9]* | aix4.1[0-9]* | aix[5-9].* | aix[1-9][0-9]*)
 122           ac_cv_sys_large_files=1 ;;
 123         esac])
 124    fi
 125   ])