m4/largefile.m4

   1 #serial 7
   2
   3 dnl By default, many hosts won't let programs access large files;
   4 dnl one must use special compiler options to get large-file access to work.
   5 dnl For more details about this brain damage please see:
   6 dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
   7
   8 dnl Written by Paul Eggert <eggert@twinsun.com>.
   9
  10 dnl Internal subroutine of AC_SYS_LARGEFILE.
  11 dnl AC_SYS_LARGEFILE_FLAGS(FLAGSNAME)
  12 AC_DEFUN(AC_SYS_LARGEFILE_FLAGS,
  13   [AC_CACHE_CHECK([for $1 value to request large file support],
  14      ac_cv_sys_largefile_$1,
  15      [if ($GETCONF LFS_$1) >conftest.1 2>conftest.2 && test ! -s conftest.2
  16       then
  17         ac_cv_sys_largefile_$1=`cat conftest.1`
  18       else
  19         ac_cv_sys_largefile_$1=no
  20         ifelse($1, CFLAGS,
  21           [case "$host_os" in
  22            # HP-UX 10.20 requires -D__STDC_EXT__ with gcc 2.95.1.
  23 [          hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)]
  24              if test "$GCC" = yes; then
  25                ac_cv_sys_largefile_CFLAGS=-D__STDC_EXT__
  26              fi
  27              ;;
  28            # IRIX 6.2 and later require cc -n32.
  29 [          irix6.[2-9]* | irix6.1[0-9]* | irix[7-9].* | irix[1-9][0-9]*)]
  30              if test "$GCC" != yes; then
  31                ac_cv_sys_largefile_CFLAGS=-n32
  32              fi
  33            esac
  34            if test "$ac_cv_sys_largefile_CFLAGS" != no; then
  35              ac_save_CC="$CC"
  36              CC="$CC $ac_cv_sys_largefile_CFLAGS"
  37              AC_TRY_LINK(, , , ac_cv_sys_largefile_CFLAGS=no)
  38              CC="$ac_save_CC"
  39            fi])
  40       fi
  41       rm -f conftest*])])
  42
  43 dnl Internal subroutine of AC_SYS_LARGEFILE.
  44 dnl AC_SYS_LARGEFILE_SPACE_APPEND(VAR, VAL)
  45 AC_DEFUN(AC_SYS_LARGEFILE_SPACE_APPEND,
  46   [case $2 in
  47    no) ;;
  48    ?*)
  49      case "[$]$1" in
  50      '') $1=$2 ;;
  51      *) $1=[$]$1' '$2 ;;
  52      esac ;;
  53    esac])
  54
  55 dnl Internal subroutine of AC_SYS_LARGEFILE.
  56 dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, CACHE-VAR, COMMENT, CODE-TO-SET-DEFAULT)
  57 AC_DEFUN(AC_SYS_LARGEFILE_MACRO_VALUE,
  58   [AC_CACHE_CHECK([for $1], $2,
  59      [$2=no
  60       $4
  61       for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
  62         case "$ac_flag" in
  63         -D$1)
  64           $2=1 ;;
  65         -D$1=*)
  66           $2=`expr " $ac_flag" : '[[^=]]*=\(.*\)'` ;;
  67         esac
  68       done
  69       ])
  70    if test "[$]$2" != no; then
  71      AC_DEFINE_UNQUOTED([$1], [$]$2, [$3])
  72    fi])
  73
  74 AC_DEFUN(AC_SYS_LARGEFILE,
  75   [AC_REQUIRE([AC_CANONICAL_HOST])
  76    AC_ARG_ENABLE(largefile,
  77      [  --disable-largefile     omit support for large files])
  78    if test "$enable_largefile" != no; then
  79      AC_CHECK_TOOL(GETCONF, getconf)
  80      AC_SYS_LARGEFILE_FLAGS(CFLAGS)
  81      AC_SYS_LARGEFILE_FLAGS(LDFLAGS)
  82      AC_SYS_LARGEFILE_FLAGS(LIBS)
  83
  84      for ac_flag in $ac_cv_sys_largefile_CFLAGS no; do
  85        case "$ac_flag" in
  86        no) ;;
  87        -D_FILE_OFFSET_BITS=*) ;;
  88        -D_LARGEFILE_SOURCE | -D_LARGEFILE_SOURCE=*) ;;
  89        -D_LARGE_FILES | -D_LARGE_FILES=*) ;;
  90        -D?* | -I?*)
  91          AC_SYS_LARGEFILE_SPACE_APPEND(CPPFLAGS, "$ac_flag") ;;
  92        *)
  93          AC_SYS_LARGEFILE_SPACE_APPEND(CFLAGS, "$ac_flag") ;;
  94        esac
  95      done
  96      AC_SYS_LARGEFILE_SPACE_APPEND(LDFLAGS, "$ac_cv_sys_largefile_LDFLAGS")
  97      AC_SYS_LARGEFILE_SPACE_APPEND(LIBS, "$ac_cv_sys_largefile_LIBS")
  98      AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS,
  99        ac_cv_sys_file_offset_bits,
 100        [Number of bits in a file offset, on hosts where this is settable.],
 101        [case "$host_os" in
 102         # HP-UX 10.20 and later
 103 [       hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)]
 104           ac_cv_sys_file_offset_bits=64 ;;
 105         esac])
 106      AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE,
 107        ac_cv_sys_largefile_source,
 108        [Define to make fseeko etc. visible, on some hosts.],
 109        [case "$host_os" in
 110         # HP-UX 10.20 and later
 111 [       hpux10.[2-9][0-9]* | hpux1[1-9]* | hpux[2-9][0-9]*)]
 112           ac_cv_sys_largefile_source=1 ;;
 113         esac])
 114      AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES,
 115        ac_cv_sys_large_files,
 116        [Define for large files, on AIX-style hosts.],
 117        [case "$host_os" in
 118         # AIX 4.2 and later
 119 [       aix4.[2-9]* | aix4.1[0-9]* | aix[5-9].* | aix[1-9][0-9]*)]
 120           ac_cv_sys_large_files=1 ;;
 121         esac])
 122    fi
 123   ])