m4/ldexpl.m4

   1 # ldexpl.m4 serial 2
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LDEXPL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   LDEXPL_LIBM=
  11   AC_CACHE_CHECK([whether ldexpl() can be used without linking with libm],
  12     [gl_cv_func_ldexpl_no_libm],
  13     [
  14       AC_TRY_LINK([#include <math.h>
  15                    long double x;],
  16                   [return ldexpl (x, -1) > 0;],
  17         [gl_cv_func_ldexpl_no_libm=yes],
  18         [gl_cv_func_ldexpl_no_libm=no])
  19     ])
  20   if test $gl_cv_func_ldexpl_no_libm = no; then
  21     AC_CACHE_CHECK([whether ldexpl() can be used with libm],
  22       [gl_cv_func_ldexpl_in_libm],
  23       [
  24         save_LIBS="$LIBS"
  25         LIBS="$LIBS -lm"
  26         AC_TRY_LINK([#include <math.h>
  27                      long double x;],
  28                     [return ldexpl (x, -1) > 0;],
  29           [gl_cv_func_ldexpl_in_libm=yes],
  30           [gl_cv_func_ldexpl_in_libm=no])
  31         LIBS="$save_LIBS"
  32       ])
  33     if test $gl_cv_func_ldexpl_in_libm = yes; then
  34       LDEXPL_LIBM=-lm
  35     fi
  36   fi
  37   if test $gl_cv_func_ldexpl_no_libm = yes \
  38      || test $gl_cv_func_ldexpl_in_libm = yes; then
  39     save_LIBS="$LIBS"
  40     LIBS="$LIBS $LDEXPL_LIBM"
  41     gl_FUNC_LDEXPL_WORKS
  42     LIBS="$save_LIBS"
  43     case "$gl_cv_func_ldexpl_works" in
  44       *yes) gl_func_ldexpl=yes ;;
  45       *)    gl_func_ldexpl=no; REPLACE_LDEXPL=1; LDEXPL_LIBM= ;;
  46     esac
  47   else
  48     gl_func_ldexpl=no
  49   fi
  50   if test $gl_func_ldexpl = yes; then
  51     AC_DEFINE([HAVE_LDEXPL], 1,
  52       [Define if the ldexpl() function is available.])
  53     dnl Also check whether it's declared.
  54     dnl MacOS X 10.3 has ldexpl() in libc but doesn't declare it in <math.h>.
  55     AC_CHECK_DECL([ldexpl], , [HAVE_DECL_LDEXPL=0], [#include <math.h>])
  56   else
  57     HAVE_DECL_LDEXPL=0
  58     AC_LIBOBJ([ldexpl])
  59   fi
  60   AC_SUBST([LDEXPL_LIBM])
  61 ])
  62
  63 dnl Test whether ldexpl() works on finite numbers (this fails on AIX 5.1).
  64 AC_DEFUN([gl_FUNC_LDEXPL_WORKS],
  65 [
  66   AC_REQUIRE([AC_PROG_CC])
  67   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  68   AC_CACHE_CHECK([whether ldexpl works], [gl_cv_func_ldexpl_works],
  69     [
  70       AC_TRY_RUN([
  71 #include <math.h>
  72 extern long double ldexpl (long double, int);
  73 int main()
  74 {
  75   volatile long double x = 1.0;
  76   volatile long double y = ldexpl (x, -1);
  77   return (y != 0.5L);
  78 }], [gl_cv_func_ldexpl_works=yes], [gl_cv_func_ldexpl_works=no],
  79       [case "$host_os" in
  80          aix*) gl_cv_func_ldexpl_works="guessing no";;
  81          *)    gl_cv_func_ldexpl_works="guessing yes";;
  82        esac
  83       ])
  84     ])
  85 ])