m4/link-follow.m4

   1 # serial 11
   2 dnl Run a program to determine whether link(2) follows symlinks.
   3 dnl Set LINK_FOLLOWS_SYMLINKS accordingly.
   4
   5 # Copyright (C) 1999-2001, 2004-2006, 2009 Free Software Foundation, Inc.
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 AC_DEFUN([gl_AC_FUNC_LINK_FOLLOWS_SYMLINK],
  11 [dnl
  12   AC_CACHE_CHECK([whether link(2) dereferences a symlink],
  13                  gl_ac_cv_func_link_follows_symlink,
  14   [
  15     # Create a regular file.
  16     echo > conftest.file
  17     AC_TRY_RUN(
  18       [
  19 #       include <sys/types.h>
  20 #       include <sys/stat.h>
  21 #       include <unistd.h>
  22 #       include <stdlib.h>
  23
  24 #       define SAME_INODE(Stat_buf_1, Stat_buf_2) \
  25           ((Stat_buf_1).st_ino == (Stat_buf_2).st_ino \
  26            && (Stat_buf_1).st_dev == (Stat_buf_2).st_dev)
  27
  28         int
  29         main ()
  30         {
  31           const char *file = "conftest.file";
  32           const char *sym = "conftest.sym";
  33           const char *hard = "conftest.hard";
  34           struct stat sb_file, sb_hard;
  35
  36           /* Create a symlink to the regular file. */
  37           if (symlink (file, sym))
  38             abort ();
  39
  40           /* Create a hard link to that symlink.  */
  41           if (link (sym, hard))
  42             abort ();
  43
  44           if (lstat (hard, &sb_hard))
  45             abort ();
  46           if (lstat (file, &sb_file))
  47             abort ();
  48
  49           /* If the dev/inode of hard and file are the same, then
  50              the link call followed the symlink.  */
  51           return SAME_INODE (sb_hard, sb_file) ? 0 : 1;
  52         }
  53       ],
  54       gl_ac_cv_func_link_follows_symlink=yes,
  55       gl_ac_cv_func_link_follows_symlink=no,
  56       gl_ac_cv_func_link_follows_symlink=yes dnl We're cross compiling.
  57     )
  58   ])
  59   if test $gl_ac_cv_func_link_follows_symlink = yes; then
  60     AC_DEFINE([LINK_FOLLOWS_SYMLINKS], [1],
  61       [Define if `link(2)' dereferences symbolic links.])
  62   fi
  63 ])