m4/locale-ja.m4

   1 # locale-ja.m4 serial 5
   2 dnl Copyright (C) 2003, 2005-2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a japanese locale with EUC-JP encoding.
  10 AC_DEFUN([gt_LOCALE_JA],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a traditional japanese locale], gt_cv_locale_ja, [
  15     macosx=
  16 changequote(,)dnl
  17     case "$host_os" in
  18       darwin[56]*) ;;
  19       darwin*) macosx=yes;;
  20     esac
  21 changequote([,])dnl
  22     if test -n "$macosx"; then
  23       # On Darwin 7 (MacOS X), the libc supports some locales in non-UTF-8
  24       # encodings, but the kernel does not support them. The documentation
  25       # says:
  26       #   "... all code that calls BSD system routines should ensure
  27       #    that the const *char parameters of these routines are in UTF-8
  28       #    encoding. All BSD system functions expect their string
  29       #    parameters to be in UTF-8 encoding and nothing else."
  30       # See the comments in config.charset. Therefore we bypass the test.
  31       gt_cv_locale_ja=none
  32     else
  33       AC_LANG_CONFTEST([AC_LANG_SOURCE([
  34 changequote(,)dnl
  35 #include <locale.h>
  36 #include <time.h>
  37 #if HAVE_LANGINFO_CODESET
  38 # include <langinfo.h>
  39 #endif
  40 #include <stdlib.h>
  41 #include <string.h>
  42 struct tm t;
  43 char buf[16];
  44 int main ()
  45 {
  46   const char *p;
  47   /* Check whether the given locale name is recognized by the system.  */
  48   if (setlocale (LC_ALL, "") == NULL) return 1;
  49   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  50      On MacOS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  51      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  52      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  53      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  54      some unit tests fail.  */
  55 #if HAVE_LANGINFO_CODESET
  56   {
  57     const char *cs = nl_langinfo (CODESET);
  58     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0)
  59       return 1;
  60   }
  61 #endif
  62 #ifdef __CYGWIN__
  63   /* On Cygwin, avoid locale names without encoding suffix, because the
  64      locale_charset() function relies on the encoding suffix.  Note that
  65      LC_ALL is set on the command line.  */
  66   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  67 #endif
  68   /* Check whether MB_CUR_MAX is > 1.  This excludes the dysfunctional locales
  69      on Cygwin 1.5.x.  */
  70   if (MB_CUR_MAX == 1)
  71     return 1;
  72   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  73      This excludes the UTF-8 encoding.  */
  74   t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  75   if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  76   for (p = buf; *p != '\0'; p++)
  77     if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  78       return 1;
  79   return 0;
  80 }
  81 changequote([,])dnl
  82         ])])
  83       if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  84         # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  85         # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  86         # configure script would override the LC_ALL setting. Likewise for
  87         # LC_CTYPE, which is also set at the beginning of the configure script.
  88         # Test for the AIX locale name.
  89         if (LC_ALL=ja_JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  90           gt_cv_locale_ja=ja_JP
  91         else
  92           # Test for the locale name with explicit encoding suffix.
  93           if (LC_ALL=ja_JP.EUC-JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  94             gt_cv_locale_ja=ja_JP.EUC-JP
  95           else
  96             # Test for the HP-UX, OSF/1, NetBSD locale name.
  97             if (LC_ALL=ja_JP.eucJP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  98               gt_cv_locale_ja=ja_JP.eucJP
  99             else
 100               # Test for the IRIX, FreeBSD locale name.
 101               if (LC_ALL=ja_JP.EUC LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 102                 gt_cv_locale_ja=ja_JP.EUC
 103               else
 104                 # Test for the Solaris 7 locale name.
 105                 if (LC_ALL=ja LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 106                   gt_cv_locale_ja=ja
 107                 else
 108                   # Special test for NetBSD 1.6.
 109                   if test -f /usr/share/locale/ja_JP.eucJP/LC_CTYPE; then
 110                     gt_cv_locale_ja=ja_JP.eucJP
 111                   else
 112                     # None found.
 113                     gt_cv_locale_ja=none
 114                   fi
 115                 fi
 116               fi
 117             fi
 118           fi
 119         fi
 120       fi
 121       rm -fr conftest*
 122     fi
 123   ])
 124   LOCALE_JA=$gt_cv_locale_ja
 125   AC_SUBST([LOCALE_JA])
 126 ])